-1

我有一个包含这个值的哈希。

哈希的名称是 PG_HASH

    {
      'PG_3' => {
                  'REFUND' => '-53702.00',
                  'PAYMENT' => '1122787.00'
                },
      'PG_1' => {
                  'REFUND' => '-72569.00',
                  'PAYMENT' => '1112523.00'
                },
    }

除此之外，我还有一个包含与哈希相关的值的数组。

@array = {
    pg_id => $pg_id,
    sum_type => $sum_type,
    sum_total => $sum_total,
    payment_ref => $payment_ref,
    payment_gateway => $payment_gateway
};

现在我想写一个带有标题的 CSV 文件：

Pg_id  TYPE    Sumtotal   TYPE1    Sumtotal
1      REFUND  -72569.00  PAYMENT  1112523.00
3      REFUND  -53702.00  PAYMENT  1122787.00

我无法将文件写入单行。我尝试迭代父哈希，但无法将其与数组匹配。

帮助

4

1 回答 1

0 
#! /usr/bin/env perl
use strict;
use warnings;
use feature 'say';
use Perl6::Form;

my %PG_HASH = (
    'PG_3' => {
        'REFUND'  => '-53702.00',
        'PAYMENT' => '1122787.00'
    },
    'PG_1' => {
        'REFUND'  => '-72569.00',
        'PAYMENT' => '1112523.00'
    },
);
my @array = (
    {
        pg_id           => 1,
        sum_type        => 'imaginary',
        sum_total       => '1000000.00',
        payment_ref     => 'imag',
        payment_gateway => '.us'
    },
    {
        pg_id           => 3,
        sum_type        => 'imaginary',
        sum_total       => '500000.00',
        payment_ref     => 'imag',
        payment_gateway => '.us'
    },
);

say "Pg_id  TYPE    Sumtotal   TYPE1    Sumtotal";
for (@array) {
  my $pg = $PG_HASH{'PG_' . $_->{pg_id}};
  print form "{<<<<} REFUND  {>>>>>>>}  PAYMENT  {>>>>>>>>}",
              $_->{pg_id}, $pg->{REFUND}, $pg->{PAYMENT};
}

say '';
say "Pg_id  TYPE      Sumtotal   TYPE1       Sumtotal";
for (keys %PG_HASH) {
  my ($id) = $_ =~ /PG_(\d+)/;
  my ($info) = grep { $_->{pg_id} == $id } @array;
  print form "{<<<<} PAYMENT  {>>>>>>>>}  SUM TOTAL  {>>>>>>>>}",
               $id, $PG_HASH{$_}{PAYMENT}, $info->{sum_total};
}

输出：

Pg_id  TYPE    Sumtotal   TYPE1    Sumtotal
1      REFUND  -72569.00  PAYMENT  1112523.00
3      REFUND  -53702.00  PAYMENT  1122787.00

Pg_id  TYPE      Sumtotal   TYPE1       Sumtotal
3      PAYMENT  1122787.00  SUM TOTAL   500000.00
1      PAYMENT  1112523.00  SUM TOTAL  1000000.00

Perl6::Form生成格式化输出（不是 CSV 输出）。按照该链接学习比我在这里做的更多。

此代码显示了参考散列对数组进行循环，以及参考数组对散列的键进行循环。

这段代码也很糟糕。

首先，它通过生成键来引用散列：'PG_' . $_->{pg_id}. 它不应该能够做到这一点。哈希不应该有这样的键。如果直接由 pg_id 键入，（因此，一个键1而不是'PG_1'），循环将读取：

for (@array) {
  my $id = $_->{pg_id};
  print form "{<<<<} REFUND  {>>>>>>>}  PAYMENT  {>>>>>>>>}",
              $id, $PG_HASH{$id}{REFUND}, $PG_HASH{$id}{PAYMENT};
}

其次，它通过为散列的每个键搜索整个数组（针对多个潜在结果而不是单个结果）来引用该数组。可能@array应该是一个散列，或者您应该处理它（即，使用第一个循环）而不是查找它的条目。

第三...名称中带有“哈希”的哈希？一个名为@array? 我相信这些不是真名。无论如何，如果对数据的来源有更多了解，就可以编写更好的代码。例如，如果您%PG_HASH从数据库查询中填充，然后@array作为记录流接收，那么您应该在添加到哈希之前3从数据库中提取PG_3，并且您应该循环遍历数组而不是哈希的键。

于 2013-03-26T13:09:46.773 回答