perl - Perl 中的动态哈希数组

Question

我有一个这样的 CSV 文件：

name,email,salary
a,b@b.com,1000
d,e@e.com,2000

现在，我需要将其转换为 Perl 中的哈希映射数组，所以当我执行以下操作时：

table[1]{"email"}

它返回 e@e.com。

我写的代码是：

open(DATA, "<$file") or die "Cannot open the file\n";
    my @table;

    #fetch header line
    $line = <DATA>;
    my @header = split(',',$line);

    #fetch data tuples
    while($line = <DATA>)
    {
        my %map;
        my @row = split(',',$line);
        for($index = 0; $index <= $#header; $index++)
        {
            $map{"$header[$index]"} = $row[$index];
        }
        push(@table, %map);
    }
    close(DATA);

但我没有得到想要的结果..你能帮忙吗？提前致谢...

Answer 1

This line

push(@table, %map)

should be

push(@table, \%map)

You want table to be a list of hash references; your code adds each key and value in %map to the list as a separate element.

Answer 2

没有必要在这里重新发明轮子。您可以使用Text::CSV模块执行此操作。

#!/usr/bin/perl

use strict;
use warnings;
use v5.16;
use Text::CSV;

my $csv = Text::CSV->new;
open my $fh, "<:encoding(utf8)", "data.csv" or die "data.csv: $!";
$csv->column_names( $csv->getline ($fh)  );
while (my $row = $csv->getline_hr ($fh)) {
    say $row->{email};
}

Answer 3

可能是这样的：

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

my @table;

chomp(my $header = <DATA>);
my @cols = split /,/, $header; # Should really use a real CSV parser here

while (<DATA>) {
  chomp;
  my %rec;
  @rec{@cols} = split /,/;
  push @table, \%rec;
}

say $table[1]{email};

__END__
name,email,salary
a,b@b.com,1000
d,e@e.com,2000