12

系统找不到alg.exe但它确实存在 - " c:\windows\system32\alg.exe"。

我最近从 Win 7 x86 转移到 x64，当我在 x86 上时，我对此没有任何问题，尝试了 Delphi 7 和 XE2。

我正在使用的代码：

if FileExists('c:\windows\system32\alg.exe') then
  ShowMessage('fe') else ShowMessage('fne');

试图以管理员权限获取文件的所有权 + 我的应用程序 - 同样的问题。

伙计们，检查x64 ..

function IsWow64Process(Handle:THandle; var IsWow64 : BOOL) : BOOL; stdcall; external 'kernel32.dll';

function IS64 : Boolean;
var
 xIS64 : Bool;
begin
 if IsWow64Process(GetCurrentProcess, xIS64) then
  Result := xIS64 else RaiseLastOSError;
end;
4

2 回答 2

17

这是因为WOW64 file system redirection，如果您的 32 位应用程序想要访问本机 system32 目录，您必须使用该Wow64DisableWow64FsRedirection函数或Sysnative别名。

Wow64DisableWow64Fs 重定向

试试这个样本

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Windows;

Function Wow64DisableWow64FsRedirection(Var Wow64FsEnableRedirection: LongBool): LongBool; StdCall;
  External 'Kernel32.dll' Name 'Wow64DisableWow64FsRedirection';
Function Wow64EnableWow64FsRedirection(Wow64FsEnableRedirection: LongBool): LongBool; StdCall;
  External 'Kernel32.dll' Name 'Wow64EnableWow64FsRedirection';

Var
  Wow64FsEnableRedirection: LongBool;
begin
 try
    if Wow64DisableWow64FsRedirection(Wow64FsEnableRedirection) then
    begin
      if FileExists('c:\windows\system32\alg.exe') then
       Writeln('fe')
      else
       Writeln('fne');

      if not Wow64EnableWow64FsRedirection(Wow64FsEnableRedirection) then
       RaiseLastOSError;
    end
    else
    RaiseLastOSError;
 except
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;

end.
end.

此外，请查看该主题的 MSDN 文档。

应用程序可以使用 Wow64DisableWow64FsRedirection、Wow64EnableWow64FsRedirection 和 Wow64RevertWow64FsRedirection 函数来控制 WOW64 文件系统重定向器。禁用文件系统重定向会影响调用线程执行的所有文件操作，因此只有在需要单个 CreateFile 调用时才应禁用它，并在函数返回后立即重新启用它。长时间禁用文件系统重定向会阻止 32 位应用程序加载系统 DLL，从而导致应用程序失败。

系统性的

32 位应用程序可以通过将 %windir%\Sysnative 替换为 %windir%\System32 来访问本机系统目录。WOW64 将 Sysnative 识别为用于指示文件系统不应重定向访问的特殊别名。这种机制灵活且易于使用，因此，建议使用绕过文件系统重定向的机制。请注意，64 位应用程序不能使用 Sysnative 别名，因为它是虚拟目录而不是真实目录。

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils,
  Windows;

begin
 try
    if FileExists('c:\windows\SysNative\alg.exe') then
     Writeln('fe')
    else
     Writeln('fne');
 except
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;

end.
于 2013-03-24T19:50:27.490 回答
13

您有一个在 64 位系统上运行的 32 位进程。您的进程在 WOW64 模拟器中运行，并受文件系统重定向器的约束。这会将对 64 位系统文件夹 %windir%\System32 的引用重定向到 32 位系统文件夹 %windir%\SysWOW64。

从模拟器下运行的 32 位进程中访问 64 位系统文件夹的推荐方法是使用 %windir%\Sysnative 别名：

32 位应用程序可以通过将 %windir%\Sysnative 替换为 %windir%\System32 来访问本机系统目录。WOW64 将 Sysnative 识别为用于指示文件系统不应重定向访问的特殊别名。这种机制灵活且易于使用，因此，建议使用绕过文件系统重定向的机制。请注意，64 位应用程序不能使用 Sysnative 别名，因为它是虚拟目录而不是真实目录。

自然，这个别名只存在于 64 位系统上。最简单的检查方法是测试 的值TOSVersion.Architecture。

虽然可以禁用重定向器，但不建议这样做。文档说：

应用程序可以使用 Wow64DisableWow64FsRedirection、Wow64EnableWow64FsRedirection 和 Wow64RevertWow64FsRedirection 函数来控制 WOW64 文件系统重定向器。禁用文件系统重定向会影响调用线程执行的所有文件操作，因此只有在需要单个 CreateFile 调用时才应禁用它，并在函数返回后立即重新启用它。长时间禁用文件系统重定向会阻止 32 位应用程序加载系统 DLL，从而导致应用程序失败。

我强烈建议您不要禁用文件系统重定向器。

于 2013-03-24T19:56:18.537 回答