regex - CMake 正则表达式匹配列表中的目录

Question

所以我有这样的文件（或值）列表

set(HEADER_FILES DirA/header1.h DirA/header2.hpp
                DirB/header3.h DirB/stuff.hpp)

那么如何仅在 DirA 中获取文件的子列表？我正在使用 CMake 2.8.x，我厌倦了正则表达式匹配：

string(REGEX MATCHALL "DirA/(.+)" DirA_FILES ${HEADER_FILES})

但结果只是原始字符串的副本，例如：“DirA/header1.h DirA/header2.hpp DirB/header3.h DirB/stuff.hpp”或什么都没有。

和往常一样，在写这个问题时我解决了它：

set(SubListMatch)
foreach(ITR ${HEADER_FILES})
    if(ITR MATCHES "(.*)DirA/(.*)")
        list(APPEND SubListMatch ${ITR})
    endif()
endforeach()

但是 CMake 对我来说是相当新的东西，那么我如何将代码包装成函数呢？到目前为止，我从未编写过任何 CMake 函数。

Answer 1

你可以把它变成这样的函数：

# Define function
function(GetSubList resultVar)
  set(result)
  foreach(ITR ${ARGN})  # ARGN holds all arguments to function after last named one
    if(ITR MATCHES "(.*)DirA/(.*)")
      list(APPEND result ${ITR})
    endif()
  endforeach()
  set(${resultVar} ${result} PARENT_SCOPE)
endfunction()

# Call it
GetSubList(SubListMatch ${HEADER_FILES})

当此代码运行时，SubListMatch将保存匹配的元素。

您可以通过例如给它一个额外的目录名称参数来改进该功能，以便其他DirA可以匹配的：

function(GetSubList resultVar dirName)
  # as before, except the if()
    if(ITR MATCHES "(.*)${dirName}/(.*)")
  # same as before
endfunction()