10

我使用一个小脚本来触发插入模式以更改行号颜色：

function! CursorLineNrColorInsert(mode)
    " Insert mode: blue
    if a:mode == "i"
        highlight CursorLineNr ctermfg=4
        highlight CursorLineNr guifg=#268bd2

    " Replace mode: red
    elseif a:mode == "r"
        highlight CursorLineNr ctermfg=1
        highlight CursorLineNr guifg=#dc322f

    else
        highlight CursorLineNr ctermfg=0
        highlight CursorLineNr guifg=#073642

    endif
endfunction

autocmd InsertEnter * call CursorLineNrColorInsert(v:insertmode)
autocmd InsertLeave * highlight CursorLineNr ctermfg=0
autocmd InsertLeave * highlight CursorLineNr guifg=#073642

当我进入任何插入模式并在正常模式下恢复为原始颜色时，它工作得很好并且会立即更改我的行号。

我想对视觉模式做同样的事情：

function! CursorLineNrColorVisual(mode)
    " Visual mode: orange
    if mode()=~#"^[vV\<C-v>]"
        highlight CursorLineNr ctermfg=9
        highlight CursorLineNr guifg=#cb4b16

    else
        highlight CursorLineNr ctermfg=0
        highlight CursorLineNr guifg=#073642

    endif
endfunction

autocmd CursorMoved * call CursorLineNrColorVisual(mode())

基本上这有效，但不是立即生效，因为该功能是在CursorMoved. 一旦激活任何视觉模式，我怎么能CursorLineNrColorVisual() 立即开火？

4

3 回答 3

10

在花了一些时间后，:help我完成了以下设置：

" Colorize line numbers in insert and visual modes
" ------------------------------------------------
function! SetCursorLineNrColorInsert(mode)
    " Insert mode: blue
    if a:mode == "i"
        highlight CursorLineNr ctermfg=4 guifg=#268bd2

    " Replace mode: red
    elseif a:mode == "r"
        highlight CursorLineNr ctermfg=1 guifg=#dc322f

    endif
endfunction


function! SetCursorLineNrColorVisual()
    set updatetime=0

    " Visual mode: orange
    highlight CursorLineNr cterm=none ctermfg=9 guifg=#cb4b16
endfunction


function! ResetCursorLineNrColor()
    set updatetime=4000
    highlight CursorLineNr cterm=none ctermfg=0 guifg=#073642
endfunction


vnoremap <silent> <expr> <SID>SetCursorLineNrColorVisual SetCursorLineNrColorVisual()
nnoremap <silent> <script> v v<SID>SetCursorLineNrColorVisual
nnoremap <silent> <script> V V<SID>SetCursorLineNrColorVisual
nnoremap <silent> <script> <C-v> <C-v><SID>SetCursorLineNrColorVisual


augroup CursorLineNrColorSwap
    autocmd!
    autocmd InsertEnter * call SetCursorLineNrColorInsert(v:insertmode)
    autocmd InsertLeave * call ResetCursorLineNrColor()
    autocmd CursorHold * call ResetCursorLineNrColor()
augroup END

为了在离开可视模式后恢复行号的颜色，我必须执行以下步骤：

  1. 重新映射相关的键绑定以调用“enter-visual-function”
  2. 进入视觉模式时，功能设置updatetime=0为CursorHold事件
  3. 通过调用“离开视觉功能”autocmd CursorHold
  4. 离开视觉模式时，功能会updatetime=4000为CursorHold事件重置
于 2013-03-23T12:54:18.367 回答
5

正如 romainl 指出的那样，没有进入/退出视觉模式的事件。我会这样做：

function! CursorLineNrColorVisual()
    ...
    return ''   " Return nothing to make the map-expr a no-op.
endfunction
vnoremap <expr> <SID>CursorLineNrColorVisual CursorLineNrColorVisual()
nnoremap <script> v v<SID>CursorLineNrColorVisual
nnoremap <script> V V<SID>CursorLineNrColorVisual
nnoremap <script> <C-v> <C-v><SID>CursorLineNrColorVisual

或者，您可以尝试将表达式 ( %{CursorLineNrColorVisual}) 放入'statusline'; 这经常被评估。

于 2013-03-22T07:44:19.493 回答
2

[编辑] Promptlines 插件使用这种方法：

由于每次更改模式时都会重新绘制状态行，因此每次更改模式时都可以通过添加状态行来触发%{AnyName(mode())}（不会显示）。然后，您可以实现一个AnyName能够过滤当前模式的函数。举个例子：

let &stl.='%{RedrawStatuslineColors(mode())}'

function! RedrawStatuslineColors(mode)
    if a:mode == 'n'
        call NormalHighlight()
    elseif a:mode == 'i'
        call InsertHighlight()
    elseif a:mode == 'R'
        call ReplaceHighlight()
    elseif a:mode == 'v' || a:mode == 'V' || a:mode == '^V'
        call VisualHighlight()
    endif
endfunction

[编辑 2] Itchyny建议在此线程上使用其他方法，以避免性能问题：建议缓存模式并RedrawStatuslineColors()立即完成功能（即。）。

于 2015-06-06T04:28:56.733 回答