0

我有一个不久前创建的当前 ODBC 链接，它正在查询 Excel 文件。我现在想做的是通过工作簿中的每个 ODBC 连接并更新连接字符串，以便它使用另一个相同名称的 .xls 文件所在的不同路径。

换句话说，我在 Excel 中看到的当前连接字符串（数据>连接>连接>1stConn 属性>定义选项卡>连接字符串）如下：

DSN=Excel Files;DBQ=C:\TEST\CurrentQuarter.xls;DefaultDir=C:\TEST;DriverId=1046;MaxBufferSize=2048;PageTimeout=5;

我希望将其更改为：

DSN=Excel Files;DBQ=C:\OTHERTEST\CurrentQuarter.xls;DefaultDir=C:\OTHERTEST;DriverId=1046;MaxBufferSize=2048;PageTimeout=5;

我试过这段代码：

Sub SwitchODBCSource()
    Dim conn As WorkbookConnection

    For Each conn In ActiveWorkbook.Connections

        With conn
            'I have tried without succes the following 2 properties, without any luck:
            .CommandText = "DSN=Excel Files;DBQ=C:\OTHERTEST\CurrentQuarter.xls;DefaultDir=C:\OTHERTEST;DriverId=1046;MaxBufferSize=2048;PageTimeout=5;"
            .Connection = "DSN=Excel Files;DBQ=C:\OTHERTEST\CurrentQuarter.xls;DefaultDir=C:\OTHERTEST;DriverId=1046;MaxBufferSize=2048;PageTimeout=5;"

        End With
    Next conn

    Set conn = Nothing

End Sub

我是否在 Connection（.CommandText 或 .Connection）上使用了适当的方法？我感觉我不是，因为 VBA 向我抛出错误“对象不支持此属性或方法”

在这种情况下，使用的对象是一个 QueryTable。我应该更改 Object 并使用那个吗？我的印象是该用户不想连接到 .xls 文件。

任何帮助将不胜感激 ！

4

2 回答 2

0

尝试conn.ODBCConnection或conn.OLEDBConnection因为它们确实具有.commandtextand.connection属性。

我不知道这是否可以让你改变它们。我原以为您需要删除然后使用新的连接字符串重新创建连接。

于 2013-03-22T03:07:46.443 回答
0

你是对的： conn.ODBCConnection.Connection 是要走的路。它让我用 VBA 改变它！惊人的。

这是一位慷慨的 MrExcel 研究员建议的代码，它运行良好（感谢 Jerry）：

Sub SwitchODBCSource()
Dim conn As WorkbookConnection
Dim sOldConnection As String, sNewConnection As String

Const sOldPath As String = "C:\TEST" '--omit trailing backslashes to change DefaultDir
Const sNewPath As String = "C:\OTHERTEST"

For Each conn In ActiveWorkbook.Connections
    With conn
        If .Type = xlConnectionTypeODBC Then
            sOldConnection = .ODBCConnection.Connection
            If InStr(1, sOldConnection, sOldPath) > 0 Then
                sNewConnection = Replace(sOldConnection, _
                        sOldPath, sNewPath, Compare:=vbTextCompare)
                .ODBCConnection.Connection = sNewConnection
                .Refresh '--optional to refresh now
            End If
        End If
      End With
Next conn

Set conn = Nothing

End Sub

谢谢尼克

塞巴斯蒂安

于 2013-03-22T13:58:51.760 回答