1

试图创建一个包含日志文件名和对应错误的数据集，其中在日志文件中包含“错误：”。日志文件位于 UNIX 上，我想访问 SAS 上的那个 unix 路径并搜索“错误：”字符串并创建一个具有日志文件名和错误的数据集。我不知道如何实现这一目标....有什么帮助吗？

在此先感谢，山姆。

这是我正在寻找的示例。假设我在 UNIX 上的 /tcrsk/dev/Logs 文件夹下有一个.log、b.log、c.log、...n.log 文件。正在尝试一个程序循环遍历所有日志文件并创建一个包含 2 个变量的数据集， LOg_Name ERROR_Message a.log ERROR:Missing b.log ERROR:No data set c.log ERROR:A lock is not avialable 我猜这个示例提供了更多详细信息....

4

2 回答 2

3

在不了解您的文件夹结构的情况下，我无法评论问题的第一部分。一旦你的日志文件的名称是已知的，你可以使用类似下面的东西。

下面的代码创建了 2 个数据集。第一个只是完整的日志，日志中每行一个观察。第二个数据集仅包含那些被标识为“错误”的行。请注意，我将某些警告和注释语句视为错误，因为它们可能会隐藏代码中的拼写错误或其他语法或语义问题：

%let logfile = myfile.log;

**
** READ IN LOGFILE. CHECK FOR PROBLEMS
*;

data problems log;
  length line $1000;

  infile "&logfile";
  input;

  logfile = "&logfile";
  line_no = _n_;
  line    = _infile_;
  problem = 0;

  if 
  (
     line =: "ERROR:"
  or line =: "WARNING:"
  or line =: "NOTE: Numeric values have been converted to character values"
  or line =: "NOTE: Character values have been converted to numeric values"
  or line =: "NOTE: Missing values were generated as a result of performing an operation on missing values"
  or line =: "NOTE: MERGE statement has more than one data set with repeats of BY values"
  or line =: "NOTE: Invalid (or missing) arguments to the INTNX function have caused the function to return"
  or line =: "INFO: Character variables have defaulted to a length of 200"
  or line =: "NOTE: Invalid"
  )
  and not
  (
      line =: "WARNING: Your system is scheduled to expire"
  or  line =: "WARNING: The Base Product product with which Session Manager is associated"
  or  line =: "WARNING: will be expiring soon, and is currently in warning mode to indicate"
  or  line =: "WARNING: this upcoming expiration. Please run PROC SETINIT to obtain more"
  or  line =: "WARNING: information on your warning period."
  or  line =: "WARNING: This CREATE TABLE statement recursively references the target table. A consequence"
  or  line =: "WARNING: Unable to copy SASUSER registry to WORK registry. Because of this, you will not see registry customizations during this"
  or  line =: "ERROR: A lock is not available for"
  or  line =: "ERROR: Errors printed on page"
  )
  then do;
    problem = 1;
    output problems;
  end;
  output log;
run;
于 2013-03-20T19:33:08.220 回答
0 
/*Creating a dat file with the list of .log files and ERROR: in their body*/    
X 'ls -1 /fbrms01/dev/Logs/*.log | xargs grep -l "ERROR:"  
                                                > /fbrms01/dev/Logs/log_error.dat';
    data log_list; **Accessing dat fil from UNIX and creating dataset on SAS;
    infile '/fbrms01/dev/Logs/log_error.dat' dsd dlm='|' lrecl=1024; 
    input Lname :$75.; 
    run;
    options symbolgen mprint mlogic;
    %macro logfile(DS);
    %let dsid = %sysfunc(open(&DS));
    /*%let obs = %sysfunc(attrn(&dsid,nobs));**To get number of observations in log_list;*/
    Proc datasets;
    Delete  All_Errors;
    %do %while (%sysfunc(fetch(&dsid)) = 0);/*To run the loop thru log_list till the end of obs*/
    %let logfile = %sysfunc(getvarc(&dsid,1));/*To get value */
            data problems ;
                length line $1000 logfile $100;
                infile "&logfile";
                input;
                logfile = "&logfile";
                line_no = _n_;
                line    = _infile_;

                if line =: "ERROR:" then do;
                output problems;
                end;
            run;
            Proc Append Base=All_Errors data=Problems force;
            Run;
        %end;
    %MEND;
    %logfile(log_list);

让我知道它是否需要任何补充......谢谢，山姆。

于 2013-03-21T19:58:00.803 回答