map - 在 Clojure 映射中“更新”给定键的惯用方式？

Question

假设我们有一张看起来像这样的地图：

(def m {:a {:foo "bar"}})

现在我们想用一些新值更新键 :a in m ：

(def vs {:baz "qux"})

如果这是 Python，我们可以执行以下操作：

>>> d = {'a': {'foo': 'bar'}}
>>> d['a'].update({'baz': 'qux'})
>>> d
{'a': {'foo': 'bar', 'baz': 'qux'}}

我发现的最简单的 Clojure 等价物是定义这样的函数：

(defn update-key
  "
  Updates a given key `k` over a map `m` with a map of values `vs`.
  "
  [k m vs]
  (assoc m k (merge (k m) vs)))

然后调用如下：

(update-key :a m vs)
; => {:a {:foo "bar" :baz "qux"}}

update()所以我的问题是：实现与Python dicts 提供的方法相同的功能的最惯用和正确的方法是什么？

score 14 · Accepted Answer

我想你正在寻找assoc-in：

(def m {:a {:foo "bar"}})

(assoc-in m [:a :foo] "qux")
; => {:a {:foo "qux"}}

(assoc-in m [:a :baz] "qux")
; => {:a {:foo "bar", :baz "qux"}}

update-in是相似的，也可能值得一看。这实际上可能更接近您的 Python 示例：

(def m {:a {:foo "bar"}})
(def vs {:baz "qux"})

(update-in m [:a] merge vs)
; => {:a {:foo "bar", :baz "qux"}}

更新：

即使键是变量值（不是编译时常量），您仍然可以同时使用两者update-in，assoc-in并将变量放入向量中：

(def m {:a {:foo "bar"}})
(def k' :baz)
(def v' "qux")

(assoc-in m [:a k'] v')
; => {:a {:foo "bar", :baz "qux"}}

您还可以以编程方式构建密钥向量：

(def m {:a {:foo "bar"}})
(def k' :baz)
(def v' "qux")

(let [ks (conj [:a] k')]
  (assoc-in m ks v'))
; => {:a {:foo "bar", :baz "qux"}}

1 回答 1