1

我正在尝试使用 AS3 将一些图像（正好 10 个）及其名称/详细信息加载到闪存文件中。

图像及其详细信息通过 PHP 存储，我有一个 PHP 文件，该文件创建一个 XML 文件，其中包含 mysql 数据库中准备好在 Flash 中使用的图像的详细信息和路径。

我只需要一种简单的方法来在 Flash 文件中显示这 10 个图像及其详细信息。

这是在浏览器中查看时我的 XML 文件的结构：

<XML>
<Data>
<ID>127</ID>
<Name>Example 1</Name>
<Price>12!!</Price>
<Image>../inventory_images/127.jpg</Image>
<Date>Mar 08, 2013</Date>
</Data>

有人可以帮我解决这个问题吗？

我真的被困住了。

提前致谢。

4

1 回答 1

1

好的，这是一个准系统类，可以满足您的要求：加载 xml，解析它，一个接一个地加载图像，添加图像，添加信息文本：

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class LoadImagesFromXML extends Sprite
    {

        private var _xmlList:XMLList;
        private var _loadIndex:int;
        private var _baseURL:String = "http://example.com/";

        public function LoadImagesFromXML()
        {
            loadXML();
        }

        private function loadXML():void{
            var urlLoader:URLLoader = new URLLoader();
            urlLoader.addEventListener( Event.COMPLETE, onXMLComplete );
            urlLoader.load( new URLRequest( _baseURL + "myxmlurl/images.xml" ) );
        }

        private function onXMLComplete( e:Event ):void{
            var urlLoader:URLLoader = e.target as URLLoader;
            urlLoader.removeEventListener( Event.COMPLETE, onXMLComplete );
            var xml:XML = new XML( urlLoader.data );
            loadImages( xml );
        }

        private function loadImages( xml:XML ):void{
            _loadIndex = 0;
            _xmlList = xml.Data;
            loadSingleImage();
        }

        private function loadSingleImage():void{
            var imageData:XML = _xmlList[ _loadIndex ];
            var imageURL:String = imageData.Image.toString();
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener( Event.COMPLETE, onImageComplete );
            loader.load( new URLRequest( _baseURL + imageURL ) );
        }

        private function onImageComplete( e:Event ):void{
            var loader:Loader = e.target.loader as Loader;
            loader.y = height;
            loader.contentLoaderInfo.removeEventListener( Event.COMPLETE, onImageComplete );
            addChild( loader );
            var imageData:XML = _xmlList[ _loadIndex ];
            var imageName:String = imageData.Name.toString();
            var imagePrice:String = imageData.Price.toString();
            var imageDate:String = imageData.Date.toString();
            var tf:TextField = new TextField();
            tf.autoSize = TextFieldAutoSize.LEFT;
            tf.text = imageName + ", Price: " + imagePrice + ", Date: " + imageDate;
            tf.y = height;
            addChild( tf );
            _loadIndex++;
            if ( _loadIndex < _xmlList.length() ){
                loadSingleImage();
            }
        }

    }
}

xml的结构是这样的：

<?xml version="1.0" encoding="UTF-8" ?>
<images>
    <Data>
        <ID>127</ID>
        <Name>Example 1</Name>
        <Price>12!!</Price>
        <Image>image1.png</Image>
        <Date>Mar 08, 2013</Date>
    </Data>
    <Data>
        <ID>127</ID>
        <Name>Example 2</Name>
        <Price>10!!</Price>
        <Image>image2.png</Image>
        <Date>Mar 20, 2013</Date>
    </Data>
</images>

请注意，这段代码没有任何错误处理，但你绝对应该实现一些，以防图像不存在、url 错误或出现安全错误……</p>

于 2013-03-20T14:57:25.150 回答