groovy - GPars：返回 eachParallel{}

Question

我想对每个示例字符串做很多事情，并在这里返回一些其他类型的对象整数，然后返回一些更大的类对象。

在这个例子中，我正在尝试一些简单的事情，但我得到了一个完全错误的结果。至少对于我希望得到的东西。xD

我希望得到：[6, 5, 6, 5] 但相反，我得到：[butter, bread, dragon, table]

package test

@Grab(group='org.codehaus.gpars', module='gpars', version='1.0.0')
import static groovyx.gpars.GParsPool.withPool

class Test {
    List<String> strings = new ArrayList<String>([
        "butter",
        "bread",
        "dragon",
        "table"
    ])

    def closure = { it.length() }

    def doStuff() {
        def results = withPool( 4 ) {
            strings.eachParallel{ it.length()}
        }
        println results
    }

    static main(args) {
        def test = new Test()
        test.doStuff()
    }
}

如果答案可以有一个简短的解释，那就太好了。非常感谢！

Answer 1

在 groovy 中each（以及eachParallel在 GPars 中）返回原始集合。

你想要的是collect（返回通过调用闭包创建的新集合）

所以，改变

        strings.eachParallel { it.length() }

至

        strings.collectParallel { it.length() }

（顺便提一句）

GPars 现在与 Groovy 捆绑在一起，因此您不需要@Grab，我假设您打算closure在collect?

package test

import static groovyx.gpars.GParsPool.withPool

class Test {
  List<String> strings =  [ "butter", "bread", "dragon", "table" ]

  def closure = { it.length() }

  def doStuff() {
    def results = withPool( 4 ) {
      strings.collectParallel closure
    }
    println results
  }

  static main( args ) {
    def test = new Test()
    test.doStuff()
  }
}