1

我试图less_than在 Coq 中证明一些定理。我正在使用这个归纳定义：

Inductive less_than : nat->nat->Prop :=
   | lt1 : forall a, less_than O (S a)
   | lt2 : forall a b, less_than a b -> less_than a (S b)
   | lt3 : forall a b, less_than a b -> less_than (S a) (S b).

我总是最终需要显示 lt3 的倒数，

Lemma inv_lt3, forall a b, less_than (S a) (S b) -> less_than a b.
Proof.
   ???

我被困住了，如果有人对如何进行有一些提示，我将不胜感激。

（我的归纳定义有问题less_than吗？）

谢谢！

4

1 回答 1

5

首先，您的定义less_than有点不幸，因为第二个构造函数是多余的。您应该考虑切换到更简单的：

Inductive less_than : nat -> nat -> Prop :=
| ltO : forall a, less_than O (S a)
| ltS : forall a b, less_than a b -> less_than (S a) (S b)
.

然后反转将匹配 coq 的反转，使您的证明变得微不足道：

Lemma inv_ltS: forall a b, less_than (S a) (S b) -> less_than a b.
Proof. now inversion 1. Qed.

第二个子句是多余的，因为对于每对(a, b)st。你想要一个证明less_than a b，你可以随时申请lt3 a次再申请lt1。您lt2实际上是其他两个构造函数的结果：

Ltac inv H := inversion H; subst; clear H; try tauto.

(* there is probably an easier way to do that? *)
Lemma lt2 : forall a b, less_than a b -> less_than a (S b).
Proof.
  intros a b. revert a. induction b; intros.
  inv H.
  inv H.
  apply ltO.
  apply ltS. now apply IHb.
Qed.

现在，如果您真的希望保留您的特定定义，您可以尝试以下证明：

Lemma inv_lt: forall a b, less_than (S a) (S b) -> less_than a b.
Proof.
  induction b; intros.
  inv H. inv H2.
  inv H. apply lt2. now apply IHb.
Qed.
于 2013-03-18T02:15:57.647 回答