perl - 如何在 perl 中发送 html 邮件时获得响应（成功或失败）

Question

以下是我在 perl 中发送 html 电子邮件的代码

use strict;
use warnings;

use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTP ();
use Email::Simple ();
use Email::Simple::Creator ();
use Email::MIME::CreateHTML;


my $smtpserver = 'xxx.xxx.xx';
my $smtpport = 25;
my $smtpuser   = 'xxx@test.com';
my $smtppassword = 'xxxx';

my $transport = Email::Sender::Transport::SMTP->new({
  host => $smtpserver,
  port => $smtpport,
  sasl_username => $smtpuser,
  sasl_password => $smtppassword,
});


my $html ="<div>Success</div>";
my $plain_text ="plain text";

my $email = Email::MIME->create_html(
        header => [
                From => 'test@lintotest.com',
                To => 'linodavis@gmailcom',
                Subject => 'Test Mail',
        ],
        body => $html,
        text_body => $plain_text
);

sendmail($email, { transport => $transport });

它工作正常。现在我需要找到邮件发送的响应。

为此，我将代码修改为

eval {
sendmail($email, { transport => $transport });    # this is try catch method
};
if ($@) {
        # where $@ is a object of Email::Sender::Failure
    print $@->message;
    print"\n".$@->code ;

}else{
 print "success";
}

现在让我知道，有没有更好的方法来实现这一点？

Answer 1

有两件事可以改进您的代码。

首先，尽快获取副本始终是一个好习惯$@（以防您在处理错误时所做的某些事情改变了 的值$@）。

if (my $e = $@) {
    print $e->message;
    print"\n" . $e->code;
}

其次，还值得考虑一个像Try::Tiny这样的模块，它可以让你的异常处理代码看起来更好一些。

try {
    sendmail($email, { transport => $transport });
} catch {
    # Exception is in $_
    print $_->message;
    print"\n" . $_->code;
}