2

我正在开发一个应用程序，我需要将所有 GPS 坐标存储在数据库中。我可以存储它，但只能存储最后一个坐标。

我的问题是，如何存储用户活动的所有坐标？我正在使用 WAMP 服务器。这是我的代码，它只存储最后一个坐标。请注意，我仅使用此代码存储 Long 和 Lat

protected function onUpdate(event:GeolocationEvent):void {
  trace("Update event called");
  log.text = "latitude = " + event.latitude +
    "\nlongitude = " + event.longitude +
    "\naltitude = " + event.altitude +
    "\nverticalAccuracy = " + event.verticalAccuracy +
    "\nhorizontalAccuracy = " + event.horizontalAccuracy +
    "\nspeed = " + event.speed +
    "\nheading = " + event.heading +
    "\ntimestamp = " + event.timestamp;
  lat.text="" + event.latitude;
  long.text="" + event.longitude;
  langTextInput.text = long.text
  latTextInput.text=lat.text
  gpstableService.commit();
4

1 回答 1

0

我认为您需要问自己的第一个问题是您是要在本地还是在 WAMP 服务器上存储此坐标。

如果您只在本地需要它们，那么一个简单的选择是使用本地 SharedObject（例如，您可以存储任何新位置，并将您收到事件的日期作为键）。如果你真的想使用本地数据库，那么你可以使用这样的服务：

package
{
    import flash.data.SQLConnection;
    import flash.data.SQLStatement;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.SQLEvent;

    public class DatabaseService extends EventDispatcher
    {
        public var conn:SQLConnection;

        public function DatabaseService()
        {
            conn = new SQLConnection();
            conn.addEventListener(SQLEvent.OPEN, handleConnectionSuccess);
            conn.openAsync(null);
        }

        public function addCoordinates(lat:String, long:String):void
        {
            var insertStmt:SQLStatement = new SQLStatement();
            insertStmt.sqlConnection = conn;
            var sql:String = "INSERT INTO coordinates (latitude, longitude)" +
                " VALUES (" + lat + ", " + long + ")";
            insertStmt.text = sql;
            insertStmt.addEventListener(SQLEvent.RESULT, handleInsertionResult);
            insertStmt.execute();
        }

        private function createTable():void
        {
            var createStmt:SQLStatement = new SQLStatement();
            createStmt.sqlConnection = conn;
            var sql:String = "CREATE TABLE IF NOT EXISTS coordinates " +
                "( coordId INTEGER PRIMARY KEY AUTOINCREMENT, latitude TEXT, longitude TEXT)";
            createStmt.text = sql;
            createStmt.addEventListener(SQLEvent.RESULT, handleTableCreationResult);
            createStmt.execute();
        }

        private function handleConnectionSuccess(event:SQLEvent):void
        {
            createTable();
        }

        private function handleTableCreationResult(event:SQLEvent):void
        {
            dispatchEvent(new Event(Event.COMPLETE));
        }

        private function handleInsertionResult(event:SQLEvent):void
        {
            var stmt:SQLStatement = event.target as SQLStatement;
            stmt.removeEventListener(SQLEvent.RESULT, handleInsertionResult);
            trace ("Coordinates are saved in DB");
        }
    }
}

然后，您可以在每次收到 GPS 事件时调用此服务：

    protected function onUpdate(event:GeolocationEvent):void
    {
        trace("Update event called");
        gpsTableService.addCoordinates(event.latitude, event.longitude);
    }

gpsTableService的实例在哪里DatabaseService。

如果您需要在您的服务器上发送此信息，那么您应该编写一个 PHP 脚本来处理您的请求。该脚本将负责数据库管理，即将数据存储到其中。要从您的 Flash 应用程序调用此脚本，您需要创建用户 a URLVariable、 aURLRequest和 a URLLoader。

于 2013-03-14T23:31:15.690 回答