vba - VBA - 将条件评估为字符串

Question

我遇到了一个非常奇怪的场景。在一个函数中，我将收到一串要评估的条件。

例如

(a>b and (b=2 or c!=3))

其中 a、b 和 c 是我的变量名。

我尝试并搜索了很多，但没有得到任何有意义的东西。

所以我的问题是：是否可以评估这样的字符串？如果是，请给我一些提示。

Answer 1

另一种方法，添加对Microsoft Script Control的引用

Dim vx As MSScriptControl.ScriptControl
Set vx = New MSScriptControl.ScriptControl

a = 100
b = 200
c = 300
Cond = "(a>b and (b=2 or c<>3))"

With vx
    .Language = "VBScript"
    .AddCode "function stub(a,b,c): stub=" & Cond & ": end function"

    result = .Run("stub", a, b, c)
End With

MsgBox result

请注意，您需要将 != 替换为 <>，因为前者在 VB* 中无效（和/或在 jScript 中无效）

Answer 2

这是您问题的正确答案，而不仅仅是评论。

你需要：

• Microsoft Visual Basic for Applications Extensibility x.x在 VBIDE 中设置对(Tools/References) 的引用。
• 信任对 VBA 项目对象模型的访问（使用 Google 了解如何为您的 Excel 版本执行此操作）。
• 运行initValues()然后调用getConstantValue("(a>b and (b=2 or c<>3))")

代码：

Option Explicit

Dim a As Long
Dim b As Long
Dim c As Long

Sub initValues()
    a = 3
    b = 2
    c = 4
End Sub

Function getConstantValue(constStr As String) As Variant

    Dim oMod As VBIDE.CodeModule
    Dim i As Long, _
        num As Long

    Set oMod = ThisWorkbook.VBProject.VBComponents("Module1").CodeModule

    For i = 1 To oMod.CountOfLines
        If oMod.Lines(i, 1) = "Function tempGetConstValue() As Variant" Then
            num = i + 1
            Exit For
        End If
    Next i

    oMod.InsertLines num, "tempGetConstValue = " & constStr

    getConstantValue = Application.Run("tempGetConstValue")

    oMod.DeleteLines num

End Function

Function tempGetConstValue() As Variant
End Function