1

我有一段实验代码可以完美地与串行编译和执行配合使用。当我在 ifort（在 ubuntu 上）上使用 openmp 选项编译它时，编译进行得很好，但执行突然停止。代码如下：

!!!!!!!! module
module array
implicit none
  real(kind=8),allocatable :: y(:)
end module array

module nonarray
implicit none
 real(kind=8):: aa
end module nonarray

use nonarray; use array
implicit none
integer(kind=8):: iter,i
integer(kind=8),parameter:: id=1
real(kind=8),allocatable:: yt(:)

allocate(y(id)); allocate(yt(id)); y=0.d0; yt=0.d0

aa=4.d0 !!A SYSTEM PARAMETER

 !$OMP PARALLEL PRIVATE(y,yt,iter,i)
 !$OMP DO

   loop1: do iter=1,20 !! THE INITIAL CONDITION LOOP
    call random_number(y)!! RANDOM INITIALIZATION OF THE VARIABLE

      loop2: do i=1,10000  !! ITERATION OF THE SYSTEM
       call evolve(yt)
       y=yt
      enddo loop2     !! END OF SYSTEM ITERATION

     write(1,*)aa,yt

   enddo loop1 !!INITIAL CONDITION ITERATION DONE

 !$OMP ENDDO
 !$OMP END PARALLEL
stop
end

recursive subroutine evolve(yevl)
use nonarray; use array
implicit none
integer(kind=8),parameter:: id=1
real(kind=8):: xf
real(kind=8),intent(out):: yevl(id)

  xf=aa*y(1)*(1.d0-y(1))
  yevl(1)=xf

end subroutine evolve

对于编译，我使用以下命令： ifort -openmp -fpp test.f90。

test.f90 是程序的名称。非常感谢任何建议或帮助。

4

1 回答 1

1

我不是 OMP 专家，但我认为如果子例程evolve应该在每个线程中看到不同的（私有）y，您应该将其直接从并行化代码块中传递给子例程，而不是从外部模块导入它：

module common
  use iso_fortran_env
  implicit none

  integer, parameter :: dp = real64
  real(dp) :: aa

contains

  subroutine evolve(y, yevl)
    implicit none
    real(dp), intent(in) :: y(:)
    real(dp), intent(out):: yevl(:)

    yevl(1) = aa * y(1) * (1.0_dp - y(1))

  end subroutine evolve

end module common


program test
  use common
  implicit none

  integer :: iter, i
  real(dp), allocatable :: yt(:), y(:)

  allocate(yt(1), y(1))
  y(:) = 0.0_dp
  yt(:) = 0.0_dp
  aa = 4.0_dp

  !$OMP PARALLEL DO PRIVATE(y,yt,iter,i)
  loop1: do iter = 1, 20
    call random_number(y)
    loop2: do i = 1, 10000
      call evolve(y, yt)
      y = yt
    end do loop2
    write(*,*) aa, yt
  end do loop1
  !$OMP END PARALLEL DO

end program test

只是一个额外的警告：上面的代码适用于各种编译器（nagfor 5.3.1、gfortran 4.6.3、ifort 13.0.1），但不适用于 ifort 12.1.6。所以，虽然我看不到任何明显的问题，但我可能搞砸了一些事情。

于 2013-03-13T20:57:14.213 回答