0

任何人都可以通过板载触发器帮助解决简单的 t-sql 脚本问题吗？我使用非常简单的触发器将数据从一个表复制到另一个表（这些表之间没有关系）。当我尝试在触发器创建后（从同一个脚本）第一次直接插入数据时，我得到了想要的结果，但是所有下一次尝试都失败了，下一个提示：' The current transaction cannot be committed and cannot support operations that write to the log file. Roll back the transaction.'我很困惑这是什么意思。看看下面的触发器：

CREATE TRIGGER AuthorInsert ON Author
INSTEAD OF INSERT
AS
BEGIN -- //- 1 -//
--***************** if insert was correct ********************
    IF (SELECT COUNT(*) FROM INSERTED) > 0
    BEGIN --//- 2 -//
        DECLARE @id int, @roleId int;
        DECLARE @nameId int, @reestrCodeId int, @passportDataId int, @addressId int, @phoneId int;
        SET @nameId = (SELECT INSERTED.NameID FROM INSERTED);
        SET @reestrCodeId = (SELECT INSERTED.ReestrCodeID FROM INSERTED);
        SET @passportDataId = (SELECT INSERTED.PassportDataID FROM INSERTED);
        SET @addressId = (SELECT INSERTED.AddressID FROM INSERTED);
        SET @phoneId = (SELECT INSERTED.PhoneID FROM INSERTED);
        BEGIN TRY
            INSERT INTO Role(RoleName) VALUES('Author');
        END TRY
        BEGIN CATCH
        END CATCH
        SET @roleId = (SELECT Role.RoleID FROM Role WHERE Role.RoleName = 'Author');
        INSERT INTO Employee(NameID, ReestrCodeID, RoleID, PassportDataID, AddressID, PhoneID)VALUES
                            (@nameId, @reestrCodeId, @roleId, @passportDataId, @addressId, @phoneId);
        SET @id = (SELECT Employee.EmployeID FROM Employee WHERE Employee.EmployeID = @@IDENTITY) + 1;
        INSERT INTO Author VALUES(@id, @nameId, @reestrCodeId, @passportDataId, @addressId, @phoneId);
    END -- //- 2 -//
END -- //- 1 -//

没有理由发布表格的图表，因为它非常原始（正如我在上面提到的那样，这些表格之间没有直接关系）显而易见。我的脚本有什么问题，这个奇怪的错误到底是什么意思？

4

1 回答 1

3

我不确定该BEGIN TRY块的意义是什么。很明显，您想确保有一个Role命名Author- 但您真的需要每次都在触发器中检查它吗？你不能现在填充它，并且永远不必再次检查吗？

  • 在创建/更改/引用对象时，请始终使用模式前缀。
  • 我在模块主体周围添加了适当的BEGIN/END包装器，并添加了SET NOCOUNT ON;
  • 我COUNT(*) from inserted改为IF EXISTS. 当您真的不在乎它是 1、10 还是 6000 时，没有理由费心检索实际计数。
  • 我从inserted. 正如@marc_s 指出的那样，您不能依赖它，因为触发器是按语句触发的，而不是按行触发的。因此，如果您有一个多行插入，您现有的触发器将只处理一个任意行。
  • 我删除了TRY/CATCH块。在大多数情况下，自己检查违规行为比让 SQL Server 为您检查更有效，尤其是在触发器中，因为它不仅对触发器代码有影响，而且对外部事务也有影响（如您所见） . 特别是在您的情况下，在第一次运行此触发器后可能每次都会引发异常。
  • 我不得不猜测Author. 请始终在和声明中包含您的列列表SELECTINSERT。除了该帖子中所述的原因之外，它还使其他人更容易帮助您重新编写代码。
CREATE TRIGGER dbo.AuthorInsert ON dbo.Author INSTEAD OF INSERT
AS
BEGIN
  SET NOCOUNT ON;
  IF EXISTS (SELECT 1 FROM inserted)
  BEGIN
    DECLARE @emps TABLE(id INT, NameID INT);
    DECLARE @RoleID INT;    
    SELECT @RoleID = RoleID FROM dbo.Roles WHERE RoleName = 'Author';
  
    IF @RoleID IS NULL
    BEGIN
      -- probably not necessary to do this over and over again
      -- unless someone is sabotaging your Roles table.
      INSERT dbo.Roles(RoleName) SELECT 'Author';
      SELECT @RoleID = SCOPE_IDENTITY();
    END
  
    INSERT dbo.Employee(NameID, ReestrCodeID, RoleID, PassportDataID, 
      AddressID, PhoneID) OUTPUT inserted.EmployeeID, inserted.NameID 
      INTO @emps SELECT NameID, ReestrCodeID, @RoleID, PassportDataID, 
       AddressID, PhoneID FROM inserted;
  
    -- this seems redundant. If an author is linked to an employee, 
    -- why do we need to store all of this information again?
    INSERT dbo.Author(EmployeeID, NameID, ReestrCodeID, RoleID, 
      PassportDataID, AddressID, PhoneID)
      SELECT e.id, i.NameID, i.ReestrCodeID, @RoleID, 
        i.PassportDataID, i.AddressID, i.PhoneID FROM @emps AS e
        INNER JOIN inserted AS i ON e.NameID = i.NameID;
  END
END
GO
于 2013-03-12T22:40:18.227 回答