2

我想知道如何根据下面的代码在变量内模拟模板马赫。

这个 XSLT 代码的输出我想将它存储在一个变量中，稍后在脚本中使用它：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="*">
    <xsl:element name="{local-name(.)}">
      <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="@*">
    <xsl:attribute name="{local-name(.)}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

我现在可以通过使用 2 个 XSLT 脚本来实现这一点，但我只想使用一个脚本。

XSLT 脚本应该给出相同的输出，如下所示：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:variable name="InputNew">
  <xsl:template match="*">
    <xsl:element name="{local-name(.)}">
      <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="@*">
    <xsl:attribute name="{local-name(.)}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
  </xsl:variable>

  <xsl:template match="/">
     <xsl:copy-of select="$InputNew"/>
  </xsl:template>
</xsl:stylesheet>

我知道我不能在变量中使用模板匹配，我只能使用 call-template 但我无法为此执行正确的 XSLT 代码。

编辑：这是工作脚本：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" exclude-result-prefixes="xsl soap xsi">
<xsl:output method="xml" version="1.0" encoding="iso-8859-1" indent="yes" omit-xml-declaration="yes"/>
   <xsl:strip-space elements="*"/>

    <xsl:template match ="*" mode="stripNs">
        <xsl:element name ="{local-name()}" >
            <xsl:apply-templates select ="@* | node()" mode="stripNs"/>
        </xsl:element>
    </xsl:template>


    <xsl:variable name="noNamespaces">
       <xsl:apply-templates select="soap:Envelope/soap:Body/*" mode="stripNs" />
    </xsl:variable>

    <xsl:template match="/">
       <!-- Now I can do what I want with the variable $noNamespaces -->
       <xsl:copy-of select="$noNamespaces"/>
    </xsl:template>

</xsl:stylesheet>
4

1 回答 1

1

如果您使用的是 Saxon，您应该能够使用该exslt:node-set()函数来执行此操作：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                              xmlns:exslt="http://exslt.org/common">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="*" mode="stripNs">
    <xsl:element name="{local-name(.)}">
      <xsl:apply-templates select="@* | node()" mode="stripNs"/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="@*" mode="stripNs">
    <xsl:attribute name="{local-name(.)}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>

  <xsl:template match="/">
    <!-- Apply the stripNs templates and capture the result in a variable -->
    <xsl:variable name="noNamespaces">
      <xsl:apply-templates select="*" mode="stripNs" />
    </xsl:variable>

    <!-- Now use the variable -->
    <xsl:apply-templates select="exslt:node-set($noNamespaces)/*" />
  </xsl:template>
</xsl:stylesheet>

再说一次，如果您使用的是 Saxon，您也可以使用 XSLT 2.0 并使用与上面相同的内容，但不需要使用exslt:node-set()around $noNamespaces：

<!-- Now use the variable -->
<xsl:apply-templates select="$noNamespaces/*" />
于 2013-03-12T16:09:25.050 回答