14

我正在使用 QuickCheck-2.5.1.1 进行质量检查。我正在测试两个纯函数gold :: a -> Float 和f :: a -> Float，其中的a实例是任意的。

这gold是一个参考计算，f是我正在优化的一个变体。

迄今为止，我使用 quickcheck 的大多数测试都在使用\a -> abs (gold a - f a) < 0.0001.

但是，我想在检查阈值的同时收集统计数据，因为了解平均误差和标准偏差对指导我的设计很有用。

有没有办法使用 QuickCheck 来收集这样的统计数据？

具体例子

举一个我正在寻找的东西的具体例子，假设我有以下两个函数来近似平方根：

-- Heron's method
heron :: Float -> Float
heron x = heron' 5 1
    where
      heron' n est
          | n > 0 = heron' (n-1) $ (est + (x/est)) / 2
          | otherwise = est

-- Fifth order Maclaurin series expansion
maclaurin :: Float -> Float
maclaurin x = 1 + (1/2) * (x - 1) - (1/8)*(x - 1)^2
                + (1/16)*(x - 1)^3 - (5/128)*(x - 1)^4
                + (7/256)*(x - 1)^5

对此的测试可能是：

test = quickCheck
       $ forAll (choose (1,2))
       $ \x -> abs (heron x - maclaurin x) < 0.02

因此，作为测试的副作用，我想知道的是统计数据abs (heron x - maclaurin x)（例如平均值和标准差）。

4

1 回答 1

4

感谢 Chris Kuklewicz 和 Ingo 的评论，我想出了以下内容，收集了我在示例中想要的统计信息：

resultToWeightList :: Result -> [(Double,Int)]
resultToWeightList r = [ (read s, n) | (s,n) <- labels r]

weightListMuSigma :: [(Double,Int)] -> (Double,Double)
weightListMuSigma wlst = (mu,sigma)  
  where 
    (weightSum,weightSqrSum,entryCount) = foldl addEntry (0,0,0) wlst
    addEntry (s,s2,c) (v,w) = (s + (v * w'), s2 + (v**2 * w'), c + w)
      where w' = fromIntegral w
    entryCount' = fromIntegral entryCount
    mu = weightSum / entryCount'
    var = weightSqrSum / entryCount' - mu**2
    sigma = sqrt var

quietCheckResult :: Testable prop => prop -> IO Result
quietCheckResult p = quickCheckWithResult args p
  where args = stdArgs { chatty = False }

test :: IO ()
test = do { r <- quietCheckResult $ forAll (choose (1,2)) test'
          ; let wlst = resultToWeightList r
          ; let (mu,sigma) = weightListMuSigma wlst 
          ; putStrLn $ "Average: " ++ show mu
          ; putStrLn $ "Standard Deviation: " ++ show sigma
          }
   where
     test' x = collect err (err < 0.1)
       where err = abs $ heron x - maclaurin x
于 2013-03-14T16:33:50.770 回答