3

我正在使用 Indy 10 Http Client（最新的 SVN 构建）和 SSL 处理程序（Delphi 7）来获取https://www.webtide.com/choose/jetty.jsp网站的内容。

它在 Windows 7 x64（在两个系统上测试）上运行良好，但在 WindowsXP x86（在 3 个系统上测试）上，测试应用程序只是挂在 TIdHTTP.Get() 上而没有恢复的可能性（意味着甚至在工作程序中断开连接/thread 不起作用！）。测试应用无法恢复，必须使用任务管理器关闭。

SSL 库（32 位 x86！）来自这里：http ://slproweb.com/products/Win32OpenSSL.html 但我尝试了来自不同站点的 5 个其他版本，结果相同。

这是一个包含源代码、编译后的可执行文件和 SSL 库的 zip 包：

https://www.dropbox.com/s/pd5soxon0qbnnl0/IndyTest.zip

这是源代码（表单有一个按钮和两个备忘录）：

 procedure TForm1.Button1Click(Sender: TObject);
 var IdHTTP1: TIdHTTP;
     sl : TStringList;
     SSL1: TIdSSLIOHandlerSocketOpenSSL;
 begin
   try
    try
      IdHTTP1 := TIdHTTP.Create(nil);
      sl := TStringList.Create;

      SSL1 := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
      SSL1.SSLOptions.Method := sslvSSLv23;

      with IdHTTP1 do
      begin
           ConnectTimeout := 10 * 1000;
           ReadTimeout := 10 * 1000;
           IOHandler := SSL1;

           Request.UserAgent := 'Mozilla/5.0 (X11; U; Linux i586; en-US; rv:1.7.3) Gecko/20040924 Epiphany/1.4.4 (Ubuntu)';
           Memo2.Text := 'connecting...';
           Application.ProcessMessages;
           Memo1.Text := Get('https://www.webtide.com/choose/jetty.jsp');
           Memo1.Lines.Add ('response: '+ResponseText);
           Memo2.Text := 'connected or timeout...';
      end;
    except
      On e: Exception do
           Memo2.Text := 'Exception: '+e.Message;
    end;
   finally
      IdHTTP1.Free;
      SSL1.Free;
      sl.Free;
   end;
 end;

为什么它在 WindowsXP 上崩溃/挂起？

4

1 回答 1

1

Indy 的ConnectTimeout属性只适用于connect()建立底层 TCP/IP 连接时的套接字 API 函数。 SSL_connect()稍后调用以启动 SSL 握手，这是应用程序数据，因此不受ConnectTimeout.

Indy 确实使用其ReadTimeout属性在 OpenSSL 连接上分配套接字级别的读/写超时，但仅在 Vista+ 上作为 OpenSSL 错误的解决方法。在 XP 和更早版本上，应用默认的套接字读/写超时。唯一告诉 Indy在ReadTimeout读取数据时要等待多长时间，但它并不应用于套接字本身。如果你想这样做，你可以通过TIdSocketHandle.SetSockOpt()在建立 TCP/IP 连接之后但在开始 SSL 握手之前调用方法来手动完成，例如：

procedure TForm1.Button1Click(Sender: TObject);
var
  IdHTTP1: TIdHTTP;
  SSL1: TIdSSLIOHandlerSocketOpenSSL;
begin
  try
    IdHTTP1 := TIdHTTP.Create(nil);
    try
      SSL1 := TIdSSLIOHandlerSocketOpenSSL.Create(IdHTTP1);
      SSL1.SSLOptions.Method := sslvSSLv23;

      with IdHTTP1 do
      begin
        ConnectTimeout := 10 * 1000;
        ReadTimeout := 10 * 1000;
        IOHandler := SSL1;

        OnConnected := IdHTTPConnected;
        OnStatus := IdHTTPStatus;

        Request.UserAgent := 'Mozilla/5.0 (X11; U; Linux i586; en-US; rv:1.7.3) Gecko/20040924 Epiphany/1.4.4 (Ubuntu)';

        Memo1.Text := Get('https://www.webtide.com/choose/jetty.jsp');
        Memo1.Lines.Add('response: '+ ResponseText);

        Memo2.Text := 'finished...';
      end;
    finally
      IdHTTP1.Free;
    end;
  except
    on e: Exception do
      Memo2.Text := 'Exception: ' + e.Message;
  end;
end;

procedure TForm1.IdHTTPStatus(ASender: TObject; const AStatus: TIdStatus; const AStatusText: string);
begin
  case AStatus of
    hsResolving: Memo2.Text := 'resolving...';
    hsConnecting: Memo2.Text := 'connecting...';
    hsConnected: Memo2.Text := 'connected...';
    hsDisconnecting: Memo2.Text := 'disconnecting...';
    hsDisconnected: Memo2.Text := 'disconnected...';
  end;
  Update;
end;

procedure TForm1.IdHTTPConnected(Sender: TObject);
begin
  with TIdHTTP(Sender).Socket.Binding do
  begin
    SetSockOpt(Id_SOL_SOCKET, Id_SO_RCVTIMEO, 10 * 1000);
    SetSockOpt(Id_SOL_SOCKET, Id_SO_SNDTIMEO, 10 * 1000);
  end;
end;
于 2013-03-12T21:02:32.380 回答