19

我有一个程序可以在 Windows 资源管理器中打开一个通过目录路径的文件夹：

procedure TfrmAbout.ShowFolder(strFolder: string);
begin
   ShellExecute(Application.Handle,PChar('explore'),PChar(strFolder),nil,nil,SW_SHOWNORMAL);
end;

有没有办法也传递这个文件名（完整的文件名路径或只是名称+扩展名）并在 Windows 资源管理器中打开文件夹但也被突出显示/选择？我要去的位置有很多文件，然后我需要在 Windows 中操作该文件。

4

2 回答 2

48

是的，您可以在调用时使用该/select标志explorer.exe：

ShellExecute(0, nil, 'explorer.exe', '/select,C:\WINDOWS\explorer.exe', nil,
  SW_SHOWNORMAL)

一种更花哨（也许也更可靠）的方法（uses ShellAPI, ShlObj）：

const
  OFASI_EDIT = $0001;
  OFASI_OPENDESKTOP = $0002;

{$IFDEF UNICODE}
function ILCreateFromPath(pszPath: PChar): PItemIDList stdcall; external shell32
  name 'ILCreateFromPathW';
{$ELSE}
function ILCreateFromPath(pszPath: PChar): PItemIDList stdcall; external shell32
  name 'ILCreateFromPathA';
{$ENDIF}
procedure ILFree(pidl: PItemIDList) stdcall; external shell32;
function SHOpenFolderAndSelectItems(pidlFolder: PItemIDList; cidl: Cardinal;
  apidl: pointer; dwFlags: DWORD): HRESULT; stdcall; external shell32;

function OpenFolderAndSelectFile(const FileName: string): boolean;
var
  IIDL: PItemIDList;
begin
  result := false;
  IIDL := ILCreateFromPath(PChar(FileName));
  if IIDL <> nil then
    try
      result := SHOpenFolderAndSelectItems(IIDL, 0, nil, 0) = S_OK;
    finally
      ILFree(IIDL);
    end;
end;
于 2013-03-08T18:41:17.847 回答
1

delphi.lonzu.net和swissdelphicenter的答案提供了一个更简单的解决方案。我只在 Windows 10、1909 上测试过它，但它的要点是：

uses ShellApi, ...
...
var
   FileName : TFileName;
begin
  FileName := 'c:\temp\somefile.html';

  ShellExecute(Handle, 'OPEN', 
    pchar('explorer.exe'), 
    pchar('/select, "' + FileName + '"'), 
    nil, 
    SW_NORMAL);
end;

这是简单易用的。我不知道它是否适用于旧版本的 Windows。

于 2020-04-05T22:46:49.337 回答