5

想象一下，我正在编码，并且打开了不同的拆分窗格。当我从一个缓冲区/窗格切换到另一个缓冲区/窗格时，我应该将哪些设置传递给 vimrc 以更改背景颜色？

我试过了：

autocmd BufEnter * highlight Normal ctermbg=black                                                                                                                                                                                                                              
autocmd BufLeave * highlight Normal ctermbg=white

我想补充一点，我确定我启用了 256 种颜色

4

5 回答 5

13

实际上，有一种方法可以达到这种效果。请参阅@blueyed 对这个相关问题的回答：vim - dim inactive split panes 。他提供了下面的脚本，当放置在我的 .vimrc 中时，它确实使非活动窗口的背景变暗。实际上，它使它们的背景与为 colorcolumn 指定的颜色相同（垂直线指示您所需的文本宽度）。

" Dim inactive windows using 'colorcolumn' setting
" This tends to slow down redrawing, but is very useful.
" Based on https://groups.google.com/d/msg/vim_use/IJU-Vk-QLJE/xz4hjPjCRBUJ
" XXX: this will only work with lines containing text (i.e. not '~')
" from 
if exists('+colorcolumn')
  function! s:DimInactiveWindows()
    for i in range(1, tabpagewinnr(tabpagenr(), '$'))
      let l:range = ""
      if i != winnr()
        if &wrap
         " HACK: when wrapping lines is enabled, we use the maximum number
         " of columns getting highlighted. This might get calculated by
         " looking for the longest visible line and using a multiple of
         " winwidth().
         let l:width=256 " max
        else
         let l:width=winwidth(i)
        endif
        let l:range = join(range(1, l:width), ',')
      endif
      call setwinvar(i, '&colorcolumn', l:range)
    endfor
  endfunction
  augroup DimInactiveWindows
    au!
    au WinEnter * call s:DimInactiveWindows()
    au WinEnter * set cursorline
    au WinLeave * set nocursorline
  augroup END
endif
于 2013-10-25T16:12:04.443 回答
4

你不能。这些:highlight组是全球性的；即当您有多个 window 时:split，所有窗口背景都将由相同的Normal高亮组着色。

活动窗口和非活动窗口之间的唯一区别是（闪烁）光标和不同突出显示的状态行（即StatusLinevs. StatusLineNC）。（您可以添加其他差异，例如仅'cursorline'在当前缓冲区中打开（请参阅我的CursorLineCurrentWindow 插件。））

Vim 的设计目标之一是在原始的、低颜色的控制台中与在 GUI GVIM 中一样好地工作。当您只有 16 种颜色可用时，背景颜色的区别可能会与语法突出显示发生冲突。我想这就是 Vim 没有也不会有这个功能的原因。

于 2013-03-08T07:24:14.587 回答
4

基本上肯特上面所说的会奏效——出奇地好。唯一的限制是您只能使前景色变暗。将其复制到 vimrc 中，然后调用:call ToggleDimInactiveWin().

let opt_DimInactiveWin=0
hi Inactive ctermfg=235
fun! ToggleDimInactiveWin()
    if g:opt_DimInactiveWin
        autocmd! DimWindows
        windo syntax clear Inactive
    else
        windo syntax region Inactive start='^' end='$'
        syntax clear Inactive
        augroup DimWindows
            autocmd BufEnter * syntax clear Inactive
            autocmd BufLeave * syntax region Inactive start='^' end='$'
        augroup end
    en
    let g:opt_DimInactiveWin=!g:opt_DimInactiveWin
endfun

在写这篇文章时，我必须查查几件事：

(1)windo方便地跨所有窗口执行命令

(2) augroup 定义自动命令组，可以用autocmd! group

于 2013-06-09T05:58:28.153 回答
4

Neovim 用户可以winhighlight选择。帮助文件提供了以下示例：

示例：为非当前窗口显示不同的颜色：

set winhighlight=Normal:MyNormal,NormalNC:MyNormalNC
于 2020-06-25T12:01:14.823 回答
1

就个人而言，我使用我的状态栏让我知道这一点。我使用 WinEnter 和 WinLeave 自动命令在离开时切换到非活动状态行（灰色），在进入时切换到活动状态行（亮色）。您提到的拆分窗格是vim中的窗口。这也有效，因为:help statusline它告诉我们它的设置是全局的或局部于窗口的，因此您可以使用:setlocal statusline=...orlet &l:statusline=...仅应用于当前窗口。

您的方法将不起作用，因为 a) BufEnter 和 BufLeave 不一定是您想要的事件，并且 b) 突出显示组是全局的，因此更改 Normal 的定义会针对每个窗口更改它。

于 2013-03-08T03:18:57.333 回答