0

I Hae 创建 BAT 文件

@ECHO OFF
"C:\Program Files\Microsoft SQL Server\100\DTS\Binn\dtexec.exe" /FILE "D:\New folder (2)\xslttosql\SSIS-BSMS\SSIS-BSMS\SSIS-BSMS\Package6.dtsx" /REP P >> "D:\TRX_Value.log"
exit

但我想输出D:\TRX_Value.log 动态更改的路径并提供有关文件名的时间信息，例如D:\TRX_Value-20130307-144650.log这意味着2012/03/07 14:46:50

那么有可能吗？我应该写什么样的脚本？

4

4 回答 4

3

在 BAT 文件中处理日期有些棘手。

一个简单的解决方案是使用WMIC LocalTime命令，它以一种方便的方式返回当前日期和时间，以便直接用FOR命令解析它。尝试类似的事情：

@ECHO OFF
FOR /F "skip=1 tokens=1-6" %%A IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
  SET /A DT=%%F*10000+%%D*100+%%A
  SET /A TM=%%B*100+%%C
  SET FDT=%DT%-%TM%
 )
ECHO "c:\progs\dtexec" /FILE "d:\fldr\pack.dtsx" /REP P "d:\logs\tr%FDT%.log"

检查结果并更正执行行以适合您的要求

于 2013-03-07T13:55:05.820 回答
2

我喜欢 PA 的使用 WMIC 的建议，但是有一个更简单的 WMIC 实现。

操作系统别名具有几乎与您想要的完全相同格式的 localDateTime 属性：

YYMMDDhhmmss.ffffff-zzz

其中ffffff是小数秒，zzz是时区信息。简单的子字符串操作提供所需的日期和时间格式。

@echo off
setlocal
set "ts="
for /f "skip=1" %%A in ('wmic os get localDateTime') do if not defined ts set "ts=%%A"
... your exe call ... >>"D:\TRX_Value-%ts:~0,8%-%ts:~8,6%.log"
于 2013-03-07T15:32:53.730 回答
1

Echo 将日期和时间转换为 2 个临时文件，然后将它们解析为正确的格式，并在您的命令中使用它们。

@ECHO OFF
Set CURRDATE=%TEMP%\CURRDATE.TMP
ECHO %DATE% > %CURRDATE%
Set CURRTIME=%TEMP%\CURRTIME.TMP
ECHO %TIME% > %CURRTIME%

Set PARSEDATEARG="eol=; tokens=1,2,3,4* delims=/, "
Set PARSETIMEARG="eol=; tokens=1,2,3,4,5* delims=:,., "
For /F %PARSEDATEARG% %%i in (%CURRDATE%) Do SET YYYYMMDD=%%k%%j%%i
For /F %PARSETIMEARG% %%i in (%CURRTIME%) Do SET HHMMSS=%%i%%j%%k

"C:\Program Files\Microsoft SQL Server\100\DTS\Binn\dtexec.exe" /FILE "D:\New folder (2)\xslttosql\SSIS-BSMS\SSIS-BSMS\SSIS-BSMS\Package6.dtsx" /REP P >> "D:\TRX_Value-%YYYYMMDD%-%HHMMSS%.log" exit
于 2013-03-07T14:43:43.090 回答
1

仅仅因为我喜欢挑战，这里有一个批处理脚本/JScript 混合脚本，可以按照您想要的方式格式化您的时间戳。用.bat扩展名保存它。

@if (@X)==(@Y) @end /* (batch + jscript hybrid script init)

:: *** Batch script *****

@echo off
setlocal
for /f %%I in ('cscript /nologo /e:jscript "%~f0"') do set "ts=%%I"
"C:\Program Files\Microsoft SQL Server\100\DTS\Binn\dtexec.exe" /FILE "D:\New folder (2)\xslttosql\SSIS-BSMS\SSIS-BSMS\SSIS-BSMS\Package6.dtsx" /REP P >> "D:\TRX_Value-%ts%.log"
exit /b

:: *** JScript script *****/

var d = new Date();
WScript.echo(d.getFullYear() + /\d{2}$/.exec('0' + (d.getMonth() + 1)) + /\d{2}$/.exec('0' + d.getDate()) + '-'
+ /\d{2}$/.exec('0' + d.getHours()) + /\d{2}$/.exec('0' + d.getMinutes()) + /\d{2}$/.exec('0' + d.getSeconds()));

（dbenham 是这类事情的大师。）

于 2013-03-07T14:39:09.990 回答