2

我正在自动化 RSA 软令牌转换并将转换字符串传递给 Outlook。我意识到我无法使用批处理到 Outlook 命令行将字符串转换为 URL，但这不是我的问题。我的问题是将讨厌的等号转换为它的 URL 编码等效项“%3D”。

@echo off
setlocal enableDelayedExpansion

set /p fname=Enter the Filename:
set /p pss=Enter the encryption pass:

IF NOT EXIST "%fname%".sdtid (
echo File Not Found!  Closing...
PING 1.1.1.1 -n 4 >NUL
exit
)

echo File Found! starting process...

REM tokenconverter %fname%.sdtid -iphone >> temp_batch.txt
tokenconverter %fname%.sdtid -p %pss% -iphone >> temp_batch.txt

set /p result= < temp_batch.txt
DEL temp_batch.txt
REM %result% | clip

set "stringclean1=!result:?=%%3F!"
set "stringclean2=!stringclean1::=%%3A!"
set "stringclean3=!stringclean2:/=%%2F!"

以下行无法对等号进行编码：

 set "stringclean4=!stringclean3:==%%3D!"

我试过了：

 set "stringclean4=!stringclean3:=^=%%3D!"
 set "stringclean4=!stringclean3:=%=%%3D!"

但是等号仍然未编码。 

echo Piping over to outlook..
REM passing stringclean3 since stringclean4 no worky.
pushd "C:\Program Files\Microsoft Office\Office12"
outlook.exe /c ipm.note /m "&subject=TEsT&body=%stringclean3%"

使用延迟变量扩展对等号进行 URL 编码的正确方法是什么？

任何帮助表示赞赏。提前致谢。

4

3 回答 3

3

dbenham 对使用 JScript 的 encodeURIComponent 方法有一个好主意。在这里，填充到 OP 的示例脚本中：

@echo off
setlocal

set /p fname=Enter the Filename:
set /p pss=Enter the encryption pass:

IF NOT EXIST "%fname%".sdtid (
    echo File Not Found!  Closing...
    PING 1.1.1.1 -n 4 >NUL
    exit
)

echo File Found! starting process...

echo WScript.Stdout.WriteLine(encodeURIComponent(WScript.StdIn.ReadLine()));>uri.js
for /f "delims=" %%I in (
    'tokenconverter %fname%.sdtid -p %pss% -iphone ^| cscript /nologo uri.js'
) do set "result=%%I"
del uri.js
于 2013-03-07T13:03:06.110 回答
3

=抱歉，根本不存在用于批量替换的简单解决方案:-(

使用纯批处理可以做的最好的事情是逐个字符地循环遍历字符串，并根据需要进行替换。

这是一个蛮力解决方案，有一些优化空间。但这已经足够了。它首先检查是否=存在，然后再花时间进行编码=。

:: test if string contains =
:: only take the time to encode = if it exists
set "test=a!stringClean3!"
for /f "delims=" %%S in ("!test!") do if /i "!test:%%S=%%S!" neq "!test!" (

  :: compute length of string - 1
  set end=0
  for /l %%A in (12,-1,0) do (
    set /a "end|=1<<%%A"
    for %%B in (!end!) do if "!stringClean3:~%%B,1!"=="" set /a "end&=~1<<%%A"
  )

  :: replace = with %3D
  for /l %%N in (0 1 !end!) do (
    if "!stringClean3:~%%N,1!" equ "=" (
      set "stringClean4=!stringClean4!%%3D"
    ) else (
      set "stringClean4=!stringClean4!!stringClean3:~%%N,1!"
    )
  )

) else set stringClean4=!stringClean3!


编辑

这是另一种完全不同的方法，它使用 CERTUTIL 将字符串编码和解码为十六进制。对十六进制字符串进行编码是一件简单的事情。我不认为 CERTUTIL 是随 XP 一起提供的。我不记得了，但 CERTUTIL 语法可能会根据 Windows 的版本略有变化。我在 Vista 上开发并测试了它。

set "tempFile=%temp%\replaceEqual%random%"

(>"%tempFile%.before" echo(!stringClean3!)
certutil -encodehex "%tempFile%.before" "%tempFile%.hex" >nul
>"%tempFile%.hex2" (
  for /f "usebackq tokens=1*" %%A in ("%tempFile%.hex") do (
    set ln=%%B
    set "ln=!ln:~0,48!"
    (echo !ln:3d=25 33 44!)
  )
)
certutil -decodehex "%tempFile%.hex2" "%tempFile%.after" >nul
<"%tempFile%.after" set /p "stringClean4="
del "%tempFile%.*"

使用 SET /P 读取结果会导致以下限制：

  • 字符串长度必须小于或等于 1021 个字符。
  • 字符串不能以控制字符结尾（去除尾随控制字符）
  • 字符串不能包含换行符

可以使用 FOR /F 读取结果，但是在扩展!FOR 变量时，延迟的扩展将损坏任何结果。

于 2013-03-07T02:41:37.233 回答
0 
SET result=qm?colon:slash/equal=qm?colon:slash/equal=end
set "stringclean0=!result!"
:loop3D
FOR /f "tokens=1,2*delims==" %%i IN ('SET stringclean0') DO (
  IF NOT "%%k"=="" set stringclean0=%%j%%3D%%k&GOTO loop3D
)
set "stringclean1=!stringclean0:?=%%3F!"
set "stringclean2=!stringclean1::=%%3A!"
set "stringclean3=!stringclean2:/=%%2F!"

SET stri
于 2013-03-07T04:37:55.137 回答