1

问题出在 SAS 9.1.3 下，有两个数据集：A 和 B。

集合 A 是包含日期和名称的主要数据集。

data Aa;
    input date name $  ;
    datalines;
    20120102 A 
    20110102 B 
    20120102 C 
    20110102 A 
    20120102 B 
    20110102 C 
    ;

集合 B 包含我要合并到集合 A 的数据。

data B;
    input date name $  rate;
    datalines;
    20120101 A 0.01
    20120101 B 0.02
    20120101 C 0.03
    20110101 A -0.01
    20110101 B -0.02
    20110101 C -0.03
    ;

我知道 SAS proc sql 中没有 fetch xxx 行，因此我在集合 B 中添加了行数：

proc sort data = b; by descending  date  name ;run;
data b1;
    set b;
    ind = _n_;
run;

我想要做的是将B的最新费率合并到A中。我的proc sql是这样的：

proc sql;
    create table new as
    select a.*,b.rate
    from Aa a left join b1 b
    on a.name = b.name and a.date>=b.date
    group by b.ind having min(b.ind)=b.ind; 
quit;

但我的结果是这样的：

20110102 A .  

20110102 B .  

20110102 C .  

20120102 A -0.01

20120102 B -0.02 

20120102 C -0.03

预期结果是：

20110102 A -0.01  

20110102 B -0.02  

20110102 C -0.03  

20120102 A 0.01

20120102 B 0.02 

20120102 C 0.03
4

1 回答 1

1

您不需要向 B 添加行计数器，无论如何您都没有进行并排合并。

我认为这可行（我将 Aa 重命名为 A）：

proc sql;
create table C as
select _A.date, _A.name, b.rate from (
    select date, name, max(b_date) as b_date from (
        select a.*, b.rate, b.date as b_date from a
        left join b
        on a.name = b.name
           and a.date gt b.date)
    group by name, date) _A 
    left join b
    on _A.name=b.name
    and _A.b_Date=b.date;
quit;

基本概念是首先构造您的笛卡尔连接，即连接所有可能的行，其中 A.date > B.date，然后根据日期差异最小的行向下过滤，以确定哪一行/日期具有您需要的评分。然后连接回 B 表以获取速率本身。

于 2013-03-05T23:03:26.433 回答