vba - 在我自己的 vba 函数中获得没有 gosub 的返回

Question

我已经与 vba 斗争了一段时间，令人惊讶的是它并没有变得更好。我编写了以下代码，因此我可以为对象使用特殊的比较运算符。

Public Function myEquals(v As CCtypestore) As Boolean

    If v Is Nothing Then
        myEquals = False
        Return
    End If

    If Me.Acronym = v.Acronym Then
        myEquals = True
        Return
    End If

    myEquals = False
    Return
End Function

我传入的对象 v 目前是 Nothing，所以我有点期望结果是微不足道的 False。令人惊讶的是，我在没有 gosub 的情况下返回错误。任何线索为什么会这样？

Answer 1

删除Return语句！

在 VBA 中，您使用行设置返回值myEquals = ...。

总而言之，您可以将函数简化为以下代码：

Public Function myEquals(v As CCtypestore) As Boolean
    If Not v Is Nothing Then
        myEquals = (Me.Acronym = v.Acronym)
    End If
End Function

或者，使用这个：

Public Function myEquals(v As CCtypestore) As Boolean
    On Error Goto ErrorHandler
    myEquals = (Me.Acronym = v.Acronym)
    Exit Function
ErrorHandler:
    myEquals = False
End Function

Return如果您想在代码中使用直接跳转，即构建意大利面条代码，这是一个古老的遗物！请参阅帮助文件中的此示例：

Sub GosubDemo()
Dim Num
' Solicit a number from the user.
    Num = InputBox("Enter a positive number to be divided by 2.")
' Only use routine if user enters a positive number.
    If Num > 0 Then GoSub MyRoutine    
    Debug.Print Num
    Exit Sub    ' Use Exit to prevent an error.
MyRoutine:
    Num = Num/2    ' Perform the division.
    Return    ' Return control to statement.
End Sub    ' following the GoSub statement.

Answer 2

使用Exit Function而不是Return.

您也可以Exit Function通过使用类似的结构来 避免这些情况

If .... Then  
    'some code
ElseIf...Then 
   'some other code
ElseIf...Then 
   'etc 
Else  
   'final 
End if