1

抱歉这个问题我是编程的初学者，对于知道该怎么做的人来说，这可能很容易：

我需要在一个 txt 文件中创建一系列带有递增数字的链接，例如我想保持某个部分“固定”而某个部分必须更改；例如想象一下：

http://user:password@website.com/members/sets/001/somethingfixed-001.zip 在文本中以下几行应该是：

http://user:password@website.com/members/sets/002/somethingfixed-002.zip 等。

我认为必须有一种方法来生成我可以指定的那些，创建链接，保持每行中的固定部分相等，然后逐步放置 001、002、003，直到我需要它为止。

如果我可以创建一个 .bat 文件来询问我：初始链接是什么，要修复的部分是什么以及要更改的内容是什么，那就太棒了。

我会做这样的程序：

插入第一个链接，然后我粘贴它。

然后它问我固定部分是什么，我输入：.../members/sets/X/somethingfixed-Y.zip

变量 X 和 Y 的范围是多少？起始号码？然后我输入 001 然后它问我最后的数字是多少？我放了 150，它会在 txt 文件中生成链接，以便我可以使用它们。

希望很清楚。

干杯

4

2 回答 2

1

例子

这将针对第一个数字进行X，我将留下一些供您开发和学习。:)

@echo off
setlocal EnableExtensions EnableDelayedExpansion
echo LeftXRight Gen
set /p "Left=Left = "
set /p "Right=Right = "
set /p "Start=Begin = "
set /p "End=End = "
>output.txt ( <nul set /p "=" )
for /L %%A in (%Start%, 1, %End%) do (
    set "X=00%%A"
    echo !Left!!X:~-3!!Right!>>output.txt
)
endlocal

输出

LeftXRight Gen
Left = http://user:password@website.com/members/sets/
Right = /somethingfixed.zip
Start = 1
End = 10

输出.txt

http://user:password@website.com/members/sets/001/somethingfixed.zip
http://user:password@website.com/members/sets/002/somethingfixed.zip
http://user:password@website.com/members/sets/003/somethingfixed.zip
http://user:password@website.com/members/sets/004/somethingfixed.zip
http://user:password@website.com/members/sets/005/somethingfixed.zip
http://user:password@website.com/members/sets/006/somethingfixed.zip
http://user:password@website.com/members/sets/007/somethingfixed.zip
http://user:password@website.com/members/sets/008/somethingfixed.zip
http://user:password@website.com/members/sets/009/somethingfixed.zip
http://user:password@website.com/members/sets/010/somethingfixed.zip

更新

为问题添加了这个完整的解决方案。

@echo off
setlocal EnableExtensions EnableDelayedExpansion
echo LeftXMidXRight Gen
set /p "Left=Left = "
set /p "Middle=Middle = "
set /p "Right=Right = "
set /p "Start=Begin = "
set /p "End=End = "
>output.txt ( <nul set /p "=" )
for /L %%A in (%Start%, 1, %End%) do (
    set "X=00%%A"
    echo !Left!!X:~-3!!Middle!!X:~-3!!Right!>>output.txt
)
endlocal

例子

LeftXMidXRight Gen
Left = http://user:password@website.com/members/sets/
Middle = /somethingfixed-
Right = .zip
Begin = 1
End = 150

输出.txt

http://user:password@website.com/members/sets/001/somethingfixed-001.zip
http://user:password@website.com/members/sets/002/somethingfixed-002.zip
...
http://user:password@website.com/members/sets/150/somethingfixed-150.zip
于 2013-03-04T22:31:07.417 回答
0

这接近你所追求的，有几个限制..

它只能附加到 url 的末尾。

1 位和 2 位数字不是以零为前缀的。

@echo off

set /p url="Enter URL: "
set /p start="Start Number: "
set /p end="End Number: "

for /L %%X in (%start%, 1, %end% ) do echo %url% %%X >> file.txt
于 2013-03-04T22:30:43.687 回答