6

问题是我有 n 个命令行参数。总是至少有 2 个，但最大数量是无限的。第一个参数指定操作模式，第二个参数是要处理的文件。第 3 到第 n 是对文件要做的事情（可能没有，因为用户可能只想清理文件，如果你只传递 2 个参数就可以完成）。

我正在查看 Perl 中可用于处理数组的方法，但我不确定从第 3 项迭代到数组末尾的“Perlish”方式是什么。

我见过的一些选项：

  • 从数组末尾弹出，直到我找到一个不以“-”开头的元素（因为文件路径不以“-”开头，尽管我认为它可以，这可能会导致问题）。
  • 移动数组两次以删除前两个元素。无论我剩下什么，我都可以迭代，如果它的大小至少为 1。

我喜欢第二种选择，但我不知道它是否是 Perlish。既然我正在努力学习 Perl，我不妨学习在 Perl 中做事的正确方法。

4

8 回答 8

17

除了像 Sinan 写的那样使用 Getopt 模块之外，我可能会选择：

my ( $operation, $file, @things ) = @ARGV;

然后你可以：

for my $thing_to_do ( @things ) {
...
}
于 2009-10-05T15:59:18.073 回答
12

恕我直言，完成您需要的 Perlish 方法是使用CPAN 上的 Getopt 模块之一。

如果您仍然想手动完成，我会选择第二个选项（这类似于我们处理方法调用的第一个参数的方式）：

die "Must provide filename and operation\n" unless @ARGV >= 2;

my $op = shift @ARGV;
my $file = shift @ARGV;

if ( @ARGV ) {
    # handle the other arguments;
}
于 2009-10-05T15:57:19.497 回答
9

我强烈建议使用Getopt::Long来解析命令行参数。这是一个标准模块，它工作得非常棒，并且让你想要做的事情变得轻而易举。

use strict;
use warnings;
use Getopt::Long;

my $first_option = undef;
my $second_option = undef;

GetOptions ('first-option=s' => \$first_option, 
            'second-option=s' => \$second_option);

die "Didn't pass in first-option, must be xxxyyyzzz."
    if ! defined $first_option;
die "Didn't pass in second-option, must be aaabbbccc."
    if ! defined $second_option;

foreach my $arg (@ARGV) {
    ...
}

这让您有一个长选项名称，并自动为您将信息填充到变量中，并允许您对其进行测试。它甚至可以让您稍后添加额外的命令，而无需对参数进行任何额外的解析，例如添加“版本”或“帮助”选项：

# adding these to the above example...
my $VERSION = '1.000';
sub print_help { ... }

# ...and replacing the previous GetOptions with this...
GetOptions ('first-option=s' => \$first_option, 
            'second-option=s' => \$second_option)
            'version' => sub { print "Running version $VERSION"; exit 1 },
            'help' => sub { print_help(); exit 2 } );

-然后，您可以使用, --、第一个字母或整个选项在命令行中调用它，并GetOptions为您计算出来。它使你的程序更健壮，更容易理解；你可以说它更“可猜测”。最好的部分是您永远不必更改处理的代码@ARGV，因为GetOptions它将为您处理所有设置。

于 2009-10-05T16:25:46.990 回答
7

Perl 中最标准的做事方式是通过 CPAN。

所以我的第一选择是Getopt::Long。DevShed 上还有一个教程：Processing Command Line Options with Perl

于 2009-10-05T15:59:35.687 回答
6

您可以使用切片来提取第二个。到最后的项目，例如：

[dsm@localhost:~]$ perl -le 'print join ", ", @ARGV[2..$#ARGV];' 1 2 3 4 5 6 7 8 9 10 00
3, 4, 5, 6, 7, 8, 9, 10, 00
[dsm@localhost:~]$

但是，您可能应该使用shift（甚至更好，GetOpt::Long）

于 2009-10-05T16:00:02.067 回答
3

deepesz 答案是一种好方法。

您的第二个选项也没有错：

my $op     = shift; # implicit shift from @ARGV
my $file   = shift; 
my @things = @ARGV;

# iterate over @things;

您也可以跳过复制@ARGV并@things直接处理它。但是，除非脚本非常短、非常简单，并且随着时间的推移不太可能变得更加复杂，否则我会避免走太多捷径。

无论您选择 deepesz 的方法还是这个方法，很大程度上都取决于品味。

决定哪个更好实际上是一个哲学问题。问题的症结在于您是否应该修改全局变量，例如@ARGV. 有人会说，只要以高度可见的方式完成，这没什么大不了的。其他人会主张@ARGV保持原样。

由于速度或内存问题，请不要注意任何支持一种或另一种选择的人。该@ARGV数组被大多数 shell 限制为非常小的尺寸，因此使用一种方法而不是另一种方法没有显着的优化。

Getopt::Long，正如已经提到的，也是一个很好的选择。

于 2009-10-05T16:28:41.370 回答
3

一定要看看MooseX::Getopt，因为它可能会激起你对 Moosey 更多东西的兴趣！.

MooseX::Getopt 示例：

# getopt.pl

{
    package MyOptions;
    use Moose;
    with 'MooseX::Getopt';

    has oper   => ( is => 'rw', isa => 'Int', documentation => 'op doc stuff' );
    has file   => ( is => 'rw', isa => 'Str', documentation => 'about file' );
    has things => ( is => 'rw', isa => 'ArrayRef', default => sub {[]} );

    no Moose;
}

my $app = MyOptions->new_with_options;

for my $thing (@{ $app->things }) {
    print $app->file, " : ", $thing, "\n";
}

# => file.txt : item1
# => file.txt : item2
# => file.txt : item3

像这样运行时会产生上述内容：

perl getopt.pl --oper 1 --file file.txt --things item1 --things item2 --things item3


检查这些 Moose 类型... ./getopt --oper "not a number"产生：

值“不是数字”对选项操作无效（预期数字）

而且你总能免费获得一份使用清单 ;-)

用法：getopt.pl [长选项...]
         --file 关于文件的位
         --oper op 文档的东西
         - 事物

/I3az/

于 2009-10-05T18:17:02.290 回答
0

对于任何数组的更一般情况：

for(my $i=2; $i<@array; $i++) {
    print "$array[$i]\n";
}

循环遍历数组，从第三个元素（索引 2）开始。显然，您指定的具体示例，depesz 的答案是最直接和最好的。

于 2009-10-06T15:30:42.990 回答