delphi - 如何创建一个带有 Owner 的 TStringList 后代，它将自动释放 TStringList？

Question

我希望创建类似“TOwnedStringList”（类名是虚构的）之类的东西，我可以将其构造为：

sl := TOwnedStringList.Create(Self);
sl.Sorted := True;
sl.Duplicates := dupIgnore; 
sl.Add(...);
// etc...

哪里Self可能是一个表单（例如），以便所有者将自动释放 StringList。我希望能够避免给sl.Free自己打电话。

这可能吗？

Answer 1

这会有点乱。你需要做这样的事情。

type
  TOwnerComponent = class(TComponent)
  private
    FOwnedObject: TObject;
  public
    constructor Create(Owner: TComponent; OwnedObject: TObject);
    destructor Destroy; override;
  end;

  TOwnedStringList = class(TStringList)
  private
    FOwner: TOwnerComponent;
  public
    constructor Create(Owner: TComponent);
    destructor Destroy; override;
  end;

{ TOwnerComponent }

constructor TOwnerComponent.Create(Owner: TComponent; OwnedObject: TObject);
begin
  inherited Create(Owner);
  FOwnedObject := OwnedObject;
end;

destructor TOwnerComponent.Destroy;
begin
  FOwnedObject.Free;
  inherited;
end;

{ TOwnedStringList }

constructor TOwnedStringList.Create(Owner: TComponent);
begin
  inherited Create;
  if Assigned(Owner) then
    FOwner := TOwnerComponent.Create(Owner, Self);
end;

destructor TOwnedStringList.Destroy;
begin
  if Assigned(FOwner) and not (csDestroying in FOwner.ComponentState) then
  begin
    FOwner.FOwnedObject := nil;
    FOwner.Free;
  end;
  inherited;
end;

基本上，您创建一个TOwnerComponent由Owner您传递给的TOwnedStringList.Create. 当它Owner死时，它会破坏TOwnerComponent它，而后者又会破坏你的字符串列表。

Free该代码对字符串列表上的显式调用具有弹性。