perl - 从文本文件创建多维向量

Question

我有以下问题：

我有一个看起来像的文件：

1 2 4 5 7 8
3 1 3 7 8 9 10 11
2 4 1 3 5
4 5 6 7

我想创建不同的向量，其中：

vector[0][0]=1 , vector[0][1]=2, ... , vector[1][0]=3, vector[1][1]=1 etc etc

我还处于起步阶段，我尝试过：

my $file = 'file.dat';
open (INFO, $file);
my @vector = <INFO>;
close (INFO);

但它只创建一个数组来读取文件中包含的内容，而不是赋予文件元素的确切位置（正如我所期望的结果）。

Answer 1

遍历文件，拆分行并将它们放入您推送到主数组的匿名数组中：

use strict;
use warnings;
use Data::Dumper;

# Use the lines below for your real data
#my $file = 'file.dat';
#open my $fh, "<", $file or die "Cannot open $file: $!";
my @vector;
while (<DATA>) {   # replace <DATA> with <$fh>
    push @vector, [ split ];
}
print Dumper \@vector;

__DATA__
1 2 4 5 7 8
3 1 3 7 8 9 10 11
2 4 1 3 5
4 5 6 7

输出：

$VAR1 = [
          [
            '1',
            '2',
            '4',
            '5',
            '7',
            '8'
          ],
          [
            '3',
            '1',
            '3',
            '7',
            '8',
            '9',
            '10',
            '11'
          ],
          [
            '2',
            '4',
            '1',
            '3',
            '5'
          ],
          [
            '4',
            '5',
            '6',
            '7'
          ]
        ];

Answer 2

您可以非常简单地使用map正则表达式来挑选数字子字符串my @vector = map [ /\d+/g ], <FILEHANDLE>

本程序从DATA文件句柄中读取，方便演示。您通常会使用自己打开一个文件open my $fh, '<', 'myfile' or die $!并从该文件句柄中读取。

Data::Dump是否仅用于显示数据结构，否则是不必要的。

use strict;
use warnings;
use 5.010;

my @vector = map [ /\d+/g ], <DATA>;

use Data::Dump;
dd \@vector;

say "\$vector[0][0] = $vector[0][0]";
say "\$vector[0][1] = $vector[0][1]";
say "\$vector[1][0] = $vector[1][0]";
say "\$vector[1][1] = $vector[1][1]";


__DATA__
1 2 4 5 7 8
3 1 3 7 8 9 10 11
2 4 1 3 5
4 5 6 7

输出

[
  [1, 2, 4, 5, 7, 8],
  [3, 1, 3, 7 .. 11],
  [2, 4, 1, 3, 5],
  [4 .. 7],
]
$vector[0][0] = 1
$vector[0][1] = 2
$vector[1][0] = 3
$vector[1][1] = 1