3

我想以最快的方式审核我的大型网络的设备。我应该使用Nmap::ParserorNmap::Scanner吗？

我想创建一个返回 ping 以及相关操作系统足迹和标识的 IP 地址列表。

示例：

平 192.168.*.*

然后，当我成功 ping 时，将 IP 地址存储在哈希中，并猜测操作系统是什么

4

2 回答 2

8

无论你使用Nmap::Parser还是Nmap::Scanner，都必须使用 Nmap 运行相同的扫描，因此两者之间没有速度差异。

这是一个示例，使用Nmap::Scanner它可以大致完成您想要的操作，报告主机的状态并尝试在它们启动时对它们进行操作系统指纹识别，将结果存储在哈希中。您应该能够根据需要扩展它。

#!/usr/bin/perl

use strict;
use warnings;

use Nmap::Scanner;

my %network_status;

my $scanner = new Nmap::Scanner;
$scanner->register_scan_complete_event(\&scan_completed);
$scanner->guess_os();

$scanner->scan('-O 192.168.*.*');

foreach my $host ( keys %network_status ) {
    print "$host => $network_status{$host}\n";
}


sub scan_completed {
    my $self     = shift;
    my $host     = shift;

    my $hostname = $host->hostname();
    my $addresses = join(',', map {$_->addr()} $host->addresses());
    my $status = $host->status();

    print "$hostname ($addresses) is $status ";

    my $os_name = 'unknown OS';
    if ( $status eq 'up' ) {
        if ( $host->os() && $host->os()->osmatches() ) {
            my ($os_type) = $host->os()->osmatches();
            $os_name = $os_type->name();
        }
        print "($os_name)";
    }
    print "\n";

    $network_status{$addresses} = $os_name;
}
于 2009-10-05T02:51:51.113 回答
1

嗯，其中之一是您已经拥有的数据的解析器，其中之一是创建数据的扫描仪。使用可以完成您需要的工作的那个。任务的哪一部分导致了问题？

于 2009-10-04T21:57:09.813 回答