excel - 在我的进度条的 excel vba 用户窗体上隐藏关闭 [X] 按钮

Question

我创建了一个用户窗体以在宏仍在导入工作表时显示进度条

问题是用户可以按下红色的[X]按钮，该按钮将关闭并中断已完成的处理。

有没有办法隐藏这个厄运的红色按钮，以便潜在用户在它运行时没有任何令人困惑的按钮可以点击。

编辑：

我试过这个

'Find the userform's Window
Private Declare Function FindWindow Lib "user32" _
        Alias "FindWindowA" ( _
        ByVal lpClassName As String, _
        ByVal lpWindowName As String) As Long

'Get the current window style
Private Declare Function GetWindowLong Lib "user32" _
        Alias "GetWindowLongA" ( _
        ByVal hWnd As Long, _
        ByVal nIndex As Long) As Long

'Set the new window style
Private Declare Function SetWindowLong Lib "user32" _
        Alias "SetWindowLongA" ( _
        ByVal hWnd As Long, _
        ByVal nIndex As Long, _
        ByVal dwNewLong As Long) As Long

Const GWL_STYLE = -16
Const WS_SYSMENU = &H80000

我在 userform_initialize 上使用了这个

   Dim hWnd As Long, lStyle As Long

   'Which type of userform
   If Val(Application.Version) >= 9 Then
      hWnd = FindWindow("ThunderDFrame", Me.Caption)
   Else
      hWnd = FindWindow("ThunderXFrame", Me.Caption)
   End If

   'Get the current window style and turn off the Close button
   lStyle = GetWindowLong(hWnd, GWL_STYLE)
   SetWindowLong hWnd, GWL_STYLE, (lStyle And Not WS_SYSMENU)

我收到此错误消息

此代码取自此处。我不知道我做错了什么，我已经删除了评论。这是我发现的最简单的代码，所以我想将它集成到我的用户表单中。任何帮助表示赞赏。

Answer 1

下面是一个可以这样调用的例程：

subRemoveCloseButton MyForm

或从您的表格中：

subRemoveCloseButton Me 

这是您需要的代码：

Private Const mcGWL_STYLE = (-16)
Private Const mcWS_SYSMENU = &H80000

'Windows API calls to handle windows
#If VBA7 Then
    Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
#Else
    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
#End If

#If VBA7 Then
    Private Declare PtrSafe Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
#Else
    Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
#End If

#If VBA7 Then
    Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
#Else
    Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
#End If


Public Sub subRemoveCloseButton(frm As Object)
    Dim lngStyle As Long
    Dim lngHWnd As Long

    lngHWnd = FindWindow(vbNullString, frm.Caption)
    lngStyle = GetWindowLong(lngHWnd, mcGWL_STYLE)

    If lngStyle And mcWS_SYSMENU > 0 Then
        SetWindowLong lngHWnd, mcGWL_STYLE, (lngStyle And Not mcWS_SYSMENU)
    End If

End Sub

Answer 2

您可以从以下代码段中解决：

选择cmdClose按钮 在菜单栏上，选择View | Code 光标闪烁的位置，输入以下代码：

Private Sub cmdClose_Click()
  Unload Me
End Sub

在菜单栏上，选择View | Object, 返回用户窗体。

要允许用户按 Esc 键关闭表单：

选择 cmdClose 按钮​​ 在“属性”窗口中，将Cancel属性更改为True

防止用户通过单击 X 按钮关闭表单

UserForm打开后，右上角有一个X。除了使用关闭表单按钮之外，人们还可以使用 X 关闭表单。如果您想阻止这种情况，请按照以下步骤操作。

右键单击 UserForm 的空白部分View | Code 从右上方的 Procedure 下拉列表中选择 QueryClose

在光标闪烁的地方，粘贴以下示例中突出显示的代码

Private Sub UserForm_QueryClose(Cancel As Integer, _
  CloseMode As Integer)
  If CloseMode = vbFormControlMenu Then
    Cancel = True
    MsgBox "Please use the Close Form button!"
  End If
End Sub

在菜单栏上，选择View | Object, 返回用户窗体。现在，如果有人单击X用户窗体中的 ，他们将看到您的消息。

来自http://www.contextures.com/xlUserForm01.html

Answer 3

这是对@Peter Albert 上述答案的改进

• Windows API 调用现在是 Office x64 安全的
• FindWindow调用已改进为仅查找 Excel 用户窗体。原始答案中的函数搜索每个窗口类（例如资源管理器窗口和其他程序的窗口）。因此，当其他程序或资源管理器窗口的名称与用户窗体同名时，可能会删除 [x] 按钮。

---

Private Const mcGWL_STYLE = (-16)
Private Const mcWS_SYSMENU = &H80000

'Windows API calls to handle windows
Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
  
#If Win64 Then
    Private Declare PtrSafe Function GetWindowLongPtr Lib "user32" Alias "GetWindowLongPtrA" ( _
        ByVal hwnd As LongPtr, ByVal nIndex As Long) As LongPtr
    Private Declare PtrSafe Function SetWindowLongPtr Lib "user32" Alias "SetWindowLongPtrA" ( _
        ByVal hwnd As LongPtr, ByVal nIndex As Long, ByVal dwNewLong As LongPtr) As LongPtr
#Else
    Private Declare PtrSafe Function GetWindowLongPtr Lib "user32" Alias "GetWindowLongA" ( _
        ByVal hwnd As LongPtr, ByVal nIndex As Long) As LongPtr
    Private Declare PtrSafe Function SetWindowLongPtr Lib "user32" Alias "SetWindowLongA" ( _
        ByVal hwnd As LongPtr, ByVal nIndex As Long, ByVal dwNewLong As LongPtr) As LongPtr
#End If

Public Sub RemoveCloseButton(objForm As Object)
    Dim lngStyle As LongPtr
    Dim lngHWnd As LongPtr
    
    Dim lpClassName As String
    lpClassName = vbNullString
    If Val(Application.Version) >= 9 Then
       lpClassName = "ThunderDFrame"
    Else
       lpClassName = "ThunderXFrame"
    End If
    
    lngHWnd = FindWindow(lpClassName, objForm.Caption)
    lngStyle = GetWindowLongPtr(lngHWnd, mcGWL_STYLE)

    If lngStyle And mcWS_SYSMENU > 0 Then
        SetWindowLongPtr lngHWnd, mcGWL_STYLE, (lngStyle And Not mcWS_SYSMENU)
    End If
End Sub

ThunderDFrame？
Excel中的UserForms其实属于Windows类ThunderDFrame，是2002年以后微软Office应用程序中所有UserFroms的类。在此之前是ThunderXFrame。

Answer 4

询问用户是否要关闭表单 - 并丢失编辑（例如）。基于贾斯汀和彼得的想法。

Private Sub UserForm_QueryClose(Cancel As Integer, _
                            CloseMode As Integer)
Dim ans
If CloseMode = vbFormControlMenu Then
    Cancel = True
    ans = Msgbox("Cancel edit?", vbQuestion + vbYesNo)
    If ans = vbYes Then
       Me.Hide
    End if
End If
End Sub

编辑：实际上我意识到这有点离题，因为 OP 想要删除 X 选项 - 但我仍然觉得这对于交互式表单很方便。

Answer 5

我知道这是一个老问题，但是对于 OP 引用的用户表单类型，您不必删除、隐藏或禁用关闭按钮。有一个更简单的方法；）

对于没有用户交互的任何元素（按钮等）并且在完成其目的后会自行关闭的任何用户表单，只需禁用表单就可以了。

禁用用户表单：在用户表单的属性中，针对 Enabled 设置 False。用户表单将显示，直到它的代码告诉它隐藏。用户将无法对表单执行任何操作（无法关闭、无法移动等）。

另请注意，您是否希望用户能够在用户窗体仍在显示时在主窗口中执行任何其他操作，这决定了您是否设置 ShowModal。

Answer 6

禁用按钮的一种有用方法是执行以下操作：

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = 0 Then Cancel = True
End Sub

虽然这并没有摆脱按钮，但它确实使单击它一事无成。