9

我正在尝试在 VBScript 中压缩一个文件夹，但它似乎不起作用。我确定我正在正确创建头文件。

它正确创建了实际文件，只是不压缩文件夹。

任何人都有任何想法：

Sub ArchiveFolder (folder)

    Dim fso, wShell, sApp, zipFile

    Set fso = CreateObject("Scripting.FileSystemObject")
    Set wShell = CreateObject("WScript.Shell")  
    Set sApp = CreateObject("Shell.Application")
    Set zipFile = fso.CreateTextFile(folder & ".zip")

    ' Write zip file header.
    zipFile.Write "PK" & Chr(5) & Chr(6) & String(18, 0)
    zipFile.Close

    sApp.NameSpace(folder & ".zip").CopyHere folder

End Sub
4

3 回答 3

13

我在这里找到的答案。神奇之处在于Do..Loop脚本等待 Shell 完成工作的最后一个位置。

ArchiveFolder "sub\foo.zip", "..\baz"

Sub ArchiveFolder (zipFile, sFolder)

    With CreateObject("Scripting.FileSystemObject")
        zipFile = .GetAbsolutePathName(zipFile)
        sFolder = .GetAbsolutePathName(sFolder)

        With .CreateTextFile(zipFile, True)
            .Write Chr(80) & Chr(75) & Chr(5) & Chr(6) & String(18, chr(0))
        End With
    End With

    With CreateObject("Shell.Application")
        .NameSpace(zipFile).CopyHere .NameSpace(sFolder).Items

        Do Until .NameSpace(zipFile).Items.Count = _
                 .NameSpace(sFolder).Items.Count
            WScript.Sleep 1000 
        Loop
    End With

End Sub
于 2013-02-28T19:04:21.360 回答
1

检查你的论点。folder必须是要放入 zip 文件的对象的路径。如果是文件夹对象，则必须使用folder.Path，因为文件夹对象的默认方法是Name，并且CopyHere无法找到仅名称的对象。

您可以在函数中添加一些调试语句来检查：

WScript.Echo TypeName(folder)
If fso.FolderExists(folder) Then
  WScript.Echo folder & " exists."
Else
  WScript.Echo folder & " doesn't exist."
End If
于 2013-02-28T18:23:14.770 回答
0

您可以通过 %comspec% 调用外部 zip 文件

oShell.Run "%comspec% /c c:\windows\7za.exe a " & oFile &".zip " & oFile & " -tzip",,True

来源http://www.scriptlook.com/zip-large-files-in-a-directory-2/

于 2015-03-21T22:04:13.113 回答