delphi - 为什么将单分配给变体会导致 varDouble 变体？

Question

uses
  SysUtils, Variants;

var
  VariantSingle: Variant;
  VTSingle: TVarType;
  SingleTest: Single;
  VariantDouble: Variant;
  DoubleTest: Double;
  VTDouble: TVarType;

begin
  SingleTest := 1.234;
  VariantSingle := SingleTest;
  VTSingle := VarType(VariantSingle) and varTypeMask;

  DoubleTest := 1.23456;
  VariantDouble := DoubleTest;
  VTDouble := VarType(VariantDouble) and varTypeMask;

  WriteLn(Format('VarType: Single: %d, Double %d', [VTSingle, VTDouble]));
end.

上面的代码将输出：

VarType：单：5，双 5

来自 System.pas

varSingle   = $0004; { vt_r4           4 }
varDouble   = $0005; { vt_r8           5 }

因此，我希望 VTSingle 为4 - 而不是 5
我错过了什么？

Answer 1

Delphi 库选择通过调用_VarFromReal. 该函数如下所示：

procedure _VarFromReal(var V: TVarData; const Value: Real);
begin
  if (V.VType and varDeepData) <> 0 then
    VarClearDeep(V);
  V.VType := varDouble;
  V.VDouble := Value;
end;

请注意，这使用了一种varDouble. 并且包括一个隐式转换，Real它是 . 的别名Double。我不确定设计师为什么选择那条特定的路线，但这种选择的结果就是你观察到的行为。

一种制作varSingle变体的简单方法可以使用：

VariantSingle := VarAsType(SingleTest, varSingle);

虽然这会转换SingleTest为Double，然后再返回Single。

为避免这种不必要的转换，请编写您自己的助手：

function VarFromSingle(const Value: Single): Variant;
begin
  VarClear(Result);
  TVarData(Result).VSingle := Value;
  TVarData(Result).VType := varSingle;
end;

你可以这样称呼它：

VariantSingle := VarFromSingle(SingleTest);

在我看来，后一种方法是正确的解决方案。