perl - Perl 中 >nul 2>&1 的等价物？

Question

我在 Windows XP 上使用 Cygwin Perl。

>nul 2>&1Perl 中是否有相当于Batch 的功能？

请参考这里。

Answer 1

如果你有一个 shell 命令：

system("$cmd >nul 2>&1");
die $! if $? < 0;
die "Child killed by signal ".($? & 0x7F)."\n" if $? & 0x7F;
die "Child exited with error ".($? >> 8)."\n" if $? >> 8;

如果你有一个程序和参数：

use IPC::Open3 qw( open3 );

open(local *CHILD_STDIN,  '<', 'nul') or die $!;
open(local *CHILD_STDOUT, '>', 'nul') or die $!;
my $pid = open3(
   '<&CHILD_STDIN',
   '>&CHILD_STDOUT',
   undef,  # 2>&1
   $prog, @args,
);
waitpid($pid, 0);
die $! if $? < 0;
die "Child killed by signal ".($? & 0x7F)."\n" if $? & 0x7F;
die "Child exited with error ".($? >> 8)."\n" if $? >> 8;

注意：如果启动孩子时出错，则会死亡。

Answer 2

Cygwin 像 Unix 一样工作，其中 null 设备被命名/dev/null而不是nul. 运行外部命令并压制所有输出是

system("mycommand arg1 arg2 >/dev/null 2>&1") == 0
    or warn "$0: mycommand exited $?";

要绕过 shell 解析，您是否还必须自己执行重定向。

use POSIX '_exit';  # if not available, fall back to plain exit with caveats

my $pid = fork;
die "$0: fork: $!" unless defined $pid;

if ($pid) {
    if (waitpid $pid, 0 >= 0) {
        my $status = $? >> 8;
        if ($status == 13) {
            warn "$0: error starting mycommand";
        }
        else {
            warn "$0: mycommand exited $status";
        }
    }
    else {
        warn "$0: waitpid: $!";
    }
}
else {
    open STDOUT, ">",  "/dev/null"   or warn("$0: open: $!"), _exit 13;
    open STDERR, ">&", \*STDOUT      or                       _exit 13;
    exec "mycommand", "arg1", "arg2" or                       _exit 13;
}

Answer 3

正如我在回答您上一个问题时所写的，您想要的是

system('cmd /C', $exe, @parm, '1>nul', '2>nul');