perl - 如何将“哈希字符串”转换为哈希？

Question

我有哈希字符串存储在文件中{"a"=>1,"b"=>2}，我打开文件并将这个哈希字符串存储到$hash_string，我怎样才能将它转换$hash_string为$hash_string_ref = {"a"=>1,"b"=>2}？

Answer 1

简单的答案：

$ echo '{"a"=>1,"b"=>2}' > val.pl
$ perl -le 'my $foo = do "val.pl"; print $foo->{a}'
1

更好的答案：考虑使用更好的数据序列化格式，例如Storable或YAML，甚至 JSON。

Answer 2

使用Perl 安全

该模块将运行任何 perl 代码（在沙箱中）并返回结果。包括解码例如转储到文件的结构。

代码示例：

use Safe;     
my $compartment = new Safe;
my $unsafe_code = '{"a"=>1,"b"=>2}';
my $result = $compartment->reval($unsafe_code);
print join(', ', %$result); 

Answer 3

您的数据格式似乎是“任意 Perl 表达式”，这是一种非常糟糕的数据格式。为什么不使用JSON或功能更全面的YAML？

use JSON::XS qw( encode_json decode_json );

sub save_struct {
   my ($qfn, $data) = @_;
   open(my $fh, '>:raw', $qfn)
      or die("Can't create JSON file \"$qfn\": $!\n");
   print($fh encode_json($data))
      or die("Can't write JSON to file \"$qfn\": $!\n");
   close($fh)
      or die("Can't write JSON to file \"$qfn\": $!\n");
}

sub load_struct {
   my ($qfn) = @_;
   open(my $fh, '>:raw', $qfn)
      or die("Can't create JSON file \"$qfn\": $!\n");
   my $json; { local $/; $json = <$fh>; }
   return decode_json($json);
}

my $data = {"a"=>1,"b"=>2};
save_struct('file.json', $data);

...

my $data = load_struct('file.json');