php - 删除子标签名称不是值

Question

我有这种类型的 xml 文件：-

<product>
   <node>
       <region_id>
                <node>1</node>
       </region_id>
       <region_time>
                <node>27</node>
                <node>02</node>
                <node>2013</node>
       </region_time>
   </node>
</ptroduct>

我想把它们改成这种类型的东西：-

<product>
      <region_id>1</region_id>
      <region_time>27,02,2013</region_time>
</product>

我想删除<Node>只是想有上面的值

Answer 1

这种转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="node">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="node[position()>1]/text()">
   <xsl:text>,</xsl:text>
   <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<product>
    <node>
        <region_id>
            <node>1</node>
        </region_id>
        <region_time>
            <node>27</node>
            <node>02</node>
            <node>2013</node>
        </region_time></node>
</product>

产生想要的正确结果：

<product>
   <region_id>1</region_id>
   <region_time>27,02,2013</region_time>
</product>

Answer 2

以下示例将完成这项工作。

假设您有以下文件：

测试.xml

<?xml version="1.0"?>
<product>
   <node>
       <region_id>
                <node>1</node>
       </region_id>
       <region_time>
                <node>27</node>
                <node>02</node>
                <node>2013</node>
       </region_time>
   </node>
</product>

test.xsl 更新

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" 
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:strip-space elements="*"/>

 <xsl:template match="*">
  <xsl:copy>
   <xsl:apply-templates select="*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="node">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="/">
    <xsl:apply-templates />
 </xsl:template>

 <!-- from dimitre\'s xsl.thanks -->
 <xsl:template match="node[position()>1]/text()">
   <xsl:text>,</xsl:text>
   <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

xslt.php

$sourcedoc = new DOMDocument();
$sourcedoc->load('test.xml');

$stylesheet = new DOMDocument();
$stylesheet->load('test.xsl');

// create a new XSLT processor and load the stylesheet
$xsltprocessor = new XSLTProcessor();
$xsltprocessor->importStylesheet($stylesheet);

// save the new xml file
file_put_contents('test-translated.xml', $xsltprocessor->transformToXML($sourcedoc));

Answer 3

您可以编写执行以下操作的脚本

1. 删除所有空格和换行符（所以，所有内容都在一行中）。
2. 使用字符串替换，'</node><node>'用 ','替换
3. 使用字符串替换，'</node>'用 '' 和'<node>'''替换

完毕！！

您可以通过使用适当的语法在 PHP 或 Javascript 中使用它。