13

假设我有一个选项列表：

let opts = [Some 1; None; Some 4]

我想将这些转换为列表选项，例如：

  • 如果列表包含None，则结果为None
  • 否则，将收集各种整数。

对于这种特定情况（使用Core和Monad模块）编写这个相对简单：

let sequence foo =
let open Option in
let open Monad_infix in
  List.fold ~init:(return []) ~f:(fun acc x ->  
    acc >>= fun acc' -> 
    x >>= fun x' -> 
    return (x' :: acc')
    ) foo;;

但是，正如问题标题所暗示的那样，我真的很想对类型构造函数进行抽象，而不是专门针对Option. 核心似乎使用函子来提供更高种类的类型的效果，但我不清楚如何编写要在模块上抽象的函数。在 Scala 中，我会使用一个隐含的上下文来要求某些Monad[M[_]]. 我期望没有办法隐式传递模块，但我将如何明确地做到这一点？换句话说，我可以写一些近似于这个的东西：

let sequence (module M : Monad.S) foo =
let open M in
let open M.Monad_infix in
  List.fold ~init:(return []) ~f:(fun acc x ->  
    acc >>= fun acc' -> 
    x >>= fun x' -> 
    return (x' :: acc')
    ) foo;;

这是可以用一流的模块完成的吗？

编辑：好的，所以我实际上并没有尝试使用该特定代码，而且它似乎比我预期的更接近工作！似乎语法实际上是有效的，但我得到了这个结果：

Error: This expression has type 'a M.t but an expression was expected of type 'a M.t
The type constructor M.t would escape its scope

错误的第一部分似乎令人困惑，因为它们匹配，所以我猜问题出在第二部分 - 这里的问题是返回类型似乎没有确定吗？我想它取决于传入的模块 - 这是一个问题吗？有没有办法修复这个实现？

4

1 回答 1

19

首先，这是您的代码的独立版本（使用 List.fold_left标准库的遗留版本），适用于手头没有 Core 但仍想尝试编译您的示例的人。

module type MonadSig = sig
  type 'a t
  val bind : 'a t -> ('a -> 'b t) -> 'b t
  val return : 'a -> 'a t
end

let sequence (module M : MonadSig) foo =
  let open M in
  let (>>=) = bind in
  List.fold_left (fun acc x ->  
    acc >>= fun acc' -> 
    x >>= fun x' -> 
    return (x' :: acc')
  ) (return []) foo;;

您收到的错误消息意味着（可以忽略令人困惑的第一行） Mt 定义是M模块的本地定义，并且不能逃脱其范围，这将与您尝试编写的内容有关。

这是因为您使用的是一流的模块，它允许对模块进行抽象，但不允许具有依赖外观的类型，例如返回类型取决于参数的模块值，或者至少是 路径（此处M）。

考虑这个例子：

module type Type = sig
  type t
end

let identity (module T : Type) (x : T.t) = x

这是错误的。错误消息指向(x : T.t)并说：

Error: This pattern matches values of type T.t
       but a pattern was expected which matches values of type T.t
       The type constructor T.t would escape its scope

您可以做的是在对一流模块 T 进行抽象之前对所需类型进行抽象，这样就没有转义了。

let identity (type a) (module T : Type with type t = a) (x : a) = x

这依赖于显式抽象类型变量的能力a。不幸的是，这个特性还没有扩展到对高级变量的抽象。你目前不能写：

let sequence (type 'a m) (module M : MonadSig with 'a t = 'a m) (foo : 'a m list) =
  ...

解决方案是使用函子：不是在值级别工作，而是在模块级别工作，它具有更丰富的语言。

module MonadOps (M : MonadSig) = struct
  open M
  let (>>=) = bind

  let sequence foo =
    List.fold_left (fun acc x ->  
      acc >>= fun acc' -> 
      x >>= fun x' -> 
      return (x' :: acc')
    ) (return []) foo;;
end

您无需在 monad 上抽象每个 monadic 操作（sequence,map等），而是进行模块范围的抽象。

于 2013-02-26T16:05:18.757 回答