2

输入文件1：

5 5 NA
NA NA 1
2 NA 2

输入文件2：

1 1 1
2 NA 2
3 NA NA
NA 4 4
5 5 5
NA NA 6

输出：

3 NA NA
NA 4 4
NA NA 6

目的是：在 file1 中，将每一行中任何不属于集合的项NA设置为一个集合，然后在 file2 中，消除其字段在该集合中的行。有人对此有想法吗？

4

4 回答 4

2

你可以这样做grep：

$ egrep -o '[0-9]+' file1 | fgrep -wvf - file2
3 NA NA
NA 4 4
NA NA 6
于 2013-02-26T14:28:29.400 回答
2

添加任何不是“NA”的项目：

awk -f script.awk file1 file2

内容script.awk：

FNR==NR {
    for (i=1;i<=NF;i++) {
        if ($i != "NA") {
            a[$i]++
        }
    }
    next
}

{
    for (j=1;j<=NF;j++) {
        if ($j in a) {
            next
        }
    }
}1

结果：

3 NA NA
NA 4 4
NA NA 6

或者，这是单线：

awk 'FNR==NR { for (i=1;i<=NF;i++) if ($i != "NA") a[$i]++; next } { for (j=1;j<=NF;j++) if ($j in a) next }1' file1 file2
于 2013-02-26T14:22:12.540 回答
0

If the column position of the values matters:

awk '
  NR==FNR{
    for(i=1; i<=NF; i++) if($i!="NA") A[i,$i]=1
    next
  }
  {
    for(i=1; i<=NF; i++) if($i!=NA && A[i,$i]) next
    print 
  }
' file1 file2
于 2013-02-26T16:30:02.910 回答
0

awk 单线：

 

awk 'NR==FNR{for(i=1;i<=NF;i++)if($i!="NA"){a[$i];break} next}{for(i=1;i<=NF;i++)if($i in a)next;}1' file1 file2

使用您的数据：

kent$  awk 'NR==FNR{for(i=1;i<=NF;i++)if($i!="NA"){a[$i];break;} next}{for(i=1;i<=NF;i++)if($i in a)next;}1' file1 file2
3 NA NA
NA 4 4
NA NA 6
于 2013-02-26T14:25:28.780 回答