1

我正在使用 MASM 和 Visual C++，并且我正在使用 x64 进行编译。这是我的 C++ 代码：

// include directive
#include "stdafx.h"
// external functions
extern "C" int Asm();
// main function
int main()
{

    // call asm
    Asm();
    // get char, return success
    _getch();
    return EXIT_SUCCESS;
}

和我的汇编代码：

extern Sleep : proc
; code segment
.code
    ; assembly procedure
    Asm proc
        ; sleep for 1 second
        mov ecx, 1000   ; ecx = sleep time
        sub rsp, 8      ; 8 bytes of shadow space
        call Sleep      ; call sleep
        add rsp, 8      ; get rid of shadow space
        ; return
        ret
    Asm endp
end

使用断点，我已经确定了发生访问冲突的代码行：就ret在我的汇编代码中的语句之后。

额外信息：

  • 我正在使用fastcall约定将我的参数传递到Sleep（即使它被声明为stdcall），因为从我读过的内容来看，x64 将始终使用fastcall约定。

  • Asm当我摆脱Sleep相关代码时，我的程序编译并执行没有错误。

  • 即使我尝试Sleep使用stdcall约定进行调用，我仍然会收到访问冲突错误。

所以很明显，我的问题是，我如何摆脱访问冲突错误，我做错了什么？

编辑：

这是Sleep(500);在 C++ 中生成的程序集：

mov         ecx,1F4h  
call        qword ptr [__imp_Sleep (13F54B308h)]

这个生成的程序集让我感到困惑......它看起来像 fastcall，因为它将参数移动到 ecx，但同时它不会创建任何阴影空间。而且我不知道这意味着什么：
qword ptr [__imp_Sleep (13F54B308h)]。

再次编辑，完整的反汇编main。

int main()
{
000000013F991020  push        rdi  
000000013F991022  sub         rsp,20h  
000000013F991026  mov         rdi,rsp  
000000013F991029  mov         ecx,8  
000000013F99102E  mov         eax,0CCCCCCCCh  
000000013F991033  rep stos    dword ptr [rdi]  
Sleep(500); // this here is the asm generated by the compiler!
000000013F991035  mov         ecx,1F4h  
000000013F99103A  call        qword ptr [__imp_Sleep (13F99B308h)]  
// call asm
Asm();
000000013F991040  call        @ILT+5(Asm) (13F99100Ah)  
// get char, return success
_getch();
000000013F991045  call        qword ptr [__imp__getch (13F99B540h)]  
return EXIT_SUCCESS;
000000013F99104B  xor         eax,eax  
}
4

1 回答 1

6

如果Asm()是一个普通的 C/C++ 函数，例如：

void Asm()
{
    Sleep(1000);
}

以下是我的 x64 编译器为其生成的内容：

Asm proc
    push rbp          ; re-aligns the stack to a 16-byte boundary (CALL pushed 8 bytes for the caller's return address) as well as prepares for setting up a stack frame
    sub rsp, 32       ; 32 bytes of shadow space
    mov rbp, rsp      ; finalizes the stack frame using the current stack pointer
    ; sleep for 1 second
    mov ecx, 1000     ; ecx = sleep time
    call Sleep        ; call sleep
    lea rsp, [rbp+32] ; get rid of shadow space
    pop rbp           ; clears the stack frame and sets the stack pointer back to the location of the caller's return address
    ret               ; return to caller
Asm endp

MSDN 说：

调用者负责为被调用者分配参数空间，并且必须始终为 4 个寄存器参数分配足够的空间，即使被调用者没有那么多参数。

有关 x64 如何使用堆栈的更多信息，请查看以下页面：

堆栈分配

于 2013-02-26T02:56:38.600 回答