4

我有一个编码为 PC UTF-8 的文件。我想将文件转换为 PC ANSI。

我已经尝试过以下方法，但我总是将输出文件设为 PC UTF-8。

use Encode;

$infile = $ARGV[0];
open(INFILE, $infile);

my $outfile = "temp.txt";

open(OUTFILE, ">$outfile");

while(<INFILE>) {
  my $row = $_;
  chomp $row;

  $row = Encode::encode("Windows-1252", $row);
  print OUTFILE $row."\n";

}

close INFILE;
close OUTFILE;
4

2 回答 2

10

问题是您永远不会解码您编码的数据。

use strict;
use warnings;
use Encode qw( encode decode );

open(my $INFILE,  '<', $ARGV[0]) or die $!;
open(my $OUTFILE, '>', $ARGV[1]) or die $!;

while (my $utf8 = <$INFILE>) {
   my $code_points = decode('UTF-8', $utf8);    # <-- This was missing.
   my $cp1252 = encode('cp1252', $code_points);
   print $OUTFILE $cp1252;
}

但是你可以更容易地做到这一点：

use strict;
use warnings;

open(my $INFILE,  '<:encoding(UTF-8)',  $ARGV[0]) or die $!;
open(my $OUTFILE, '>:encoding(cp1252)', $ARGV[1]) or die $!;

while (<$INFILE>) {
   print $OUTFILE $_;
}
于 2013-02-25T23:24:14.673 回答
1

您应该使用 PerlIO-Layers，而不是手动进行解码和编码。binmode您可以使用该函数或在三个参数的模式参数中指定一个层open：

use strict; use warnings;
use autodie;

open my $INFILE,  '<:utf8',                 $ARGV[0];
open my $OUTFILE, '>:encoding(iso-8859-1)', "temp.txt";
#                   ^-- the layers

while (my $line = <$INFILE>) {
  print $OUTFILE $line;
}

请注意，Perl 默认情况下不会以 UTF8 格式打开文件，您还必须指定解码层。层:encoding(utf8)太普通了，可以:utf8直接说。

您可以列出所有可用的编码

use Encode;
print "$_\n" for Encode->encodings();
于 2013-02-25T22:02:32.947 回答