functional-programming - 方案 - 带有嵌套 lambda 的斐波那契数列

Question

启发了这篇文章。

我试图用嵌套的 lambda 实现一个斐波那契数列-

(( (lambda (x) (x x)) ;; evaluate x on x
    ((lambda (fibo-gen)) ;; fibo-gen get another func as arg
    (lambda (N it second first)
     (cond  ;; here the body of the above func ..
       ((= N 1) 1)
       ((= N 1) 1)
       ((= N it) (+ second first))
       (else (fibo-gen (+ it 1) (+ second first) (second)))
       )
     )
    )
   )
 5  1 1 1)

是提示r5rs:body: no expression in body in: (r5rs:body)

通过我的检查，每个功能在这里都有一个“身体”，那么我做错了什么？

请注意，我在这里尝试执行的实现是迭代模式，避免重新计算以前的系列..

编辑 ：

另一种也有效的模式 -

(( (lambda (x) (x x)) ;; evaluate x on x
    (lambda (fibo-gen) ;; fibo-gen body use another lambda ..
    (lambda (N it second first)
     (cond  ;; here the body of the above func ..
       ((= N 1) 1)
       ((= N 2) 1)
       ((= N it) second)
       (else ((fibo-gen fibo-gen) N (+ it 1) (+ second first) second))
       )
     )
    )
   )
 5 1 1 1)
 => 8

Answer 1

好吧，这是计算斐波那契的一种相当人为的方法，但仍然是可能的：

(((lambda (x) (x x))
  (lambda (fib-gen)
    (lambda (it second first)
      (if (zero? it)
          first
          ((fib-gen fib-gen) (sub1 it) (+ first second) second)))))
 10 1 0) ; here n = 10

=> 55

如果您的目标是在不使用 的情况下编写递归函数的通用方法define，请首先实现Y-Combinator：

(define (Y X)
  ((lambda (proc) (proc proc))
   (lambda (proc)
     (X (lambda args
          (apply (proc proc) args))))))

有了这个，您可以编写具有可变数量参数的匿名递归过程，例如：

((Y
  (lambda (fib-gen)
    (lambda (it second first)
      (if (zero? it)
          first
          (fib-gen (sub1 it) (+ first second) second)))))
 10 1 0)  ; here n = 10

=> 55

Answer 2

(lambda (fibo-gen))

在第二行没有正文。