bison - 获取：警告，规则无法匹配

Question

我正在构建一个词法和语法分析器。当我尝试将 flex 与 .l 文件一起使用时，我收到以下警告。

littleDuck.l:26: warning, rule cannot be matched

规则 26 是以 {cteI} 开头的规则，我的规则部分如下：

[ \t\n]     ;
{RW}        {return RESERVED;}
{id}        {return ID;}
{ops}       {return OPERATOR;}
{seps}      {return SEPARATOR;}
{cteI}      {yylval.ival = atoi(yytext); return INT;}
{cteF}      {yylval.fval = atof(yytext); return FLOAT;}
{ctestring} {yylval.sval = strdup(yytext); return STRING;}
.       ;

另外，我的定义部分是这样的：

RW      program|var|int|float|print|else|if
id      ([a-z]|[A-Z)([a-z]|[A-Z]|[0-9])*
ops     "="|"<"|">"|"<>"|"+"|"-"|"/"|"*"
seps    ":"|","|";"|"{"|"}"|"("|")"
cteI    [0-9]+
cteF    {cteI}(\.{cteI}((e|E)("+"|"-")?{cteI})?)?
ctestring   (\".*\")

为什么会出现此警告，如何修改我的文件使其不会出现？

Answer 1

警告告诉您，任何可能匹配的{cteI}内容都将始终与某个较早的规则匹配。在您的情况下，它表明规则与您期望的不匹配，可能是由于拼写错误。在您的情况下，它是{id}规则，您将其定义为：

([a-z]|[A-Z)([a-z]|[A-Z]|[0-9])*

注意括号和方括号的嵌套。为清楚起见添加空格，这是

( [a-z] | [A-Z)([a-z] | [A-Z] | [0-9] )*

这将匹配任何字母、数字或字符( )或[. 你可能的意思是：

([a-z]|[A-Z])([a-z]|[A-Z]|[0-9])*

可以更清楚地写成

[a-zA-Z][a-zA-Z0-9]*

Answer 2

查看规则的顺序，因为它很重要！

  1 [.] 
  2 "foo"

这里永远不会匹配第二条规则。