linux - 从 stat 函数输出中理解和解码文件模式值

Question

我一直试图了解下面提到的代码中到底发生了什么。但我无法理解。

$mode = (stat($filename))[2];
printf "Permissions are %04o\n", $mode & 07777;

假设我的 $mode 值为 33188

$mode & 07777 产生一个值 = 420

$mode 值是十进制数吗？
为什么我们选择 07777 以及为什么我们要进行按位运算。我无法理解这里的逻辑。

score 34 · Accepted Answer

您问题中的模式对应于具有 644 权限的常规文件（所有者为读写，其他所有人为只读），但不要相信我的话。

$ touch foo
$ chmod 644 富
$ perl -le '打印 +(stat "foo")[2]'
33188

的值$mode 可以看作是十进制整数，但这样做并不是特别有启发性。看到八进制表示会让人更熟悉一些。

$ perl -e 'printf "%o\n", (stat "foo")[2]'
100644

按位与 07777 给出数字二进制表示的最后 12 位。对于 Unix 模式，此操作提供权限或模式位并丢弃任何类型信息。

$ perl -e 'printf "%d\n", (stat "foo")[2] & 07777' # 十进制，没用
420
$ perl -e 'printf "%o\n", (stat "foo")[2] & 07777' # 八进制，尤里卡！
644

下面是一个更好的方法。请继续阅读以了解所有详细信息。

模式位

stat从（对应于st_modein ）返回的第三个元素struct stat是一个位字段，其中不同的位位置是二进制标志。

例如，st_modePOSIX names中的一位S_IWUSR。模式设置了该位的文件或目录可由其所有者写入。相关的一点是S_IROTH，当设置意味着其他用户（即，既不是所有者也不是组中的用户）可以读取该特定文件或目录。

perlfunc 文档stat给出了常用模式位的名称。我们可以检查它们的值。

#! /usr/bin/env perl

use strict;
use warnings;
use Fcntl ':mode';

my $perldoc_f_stat = q(
  # Permissions: read, write, execute, for user, group, others.
  S_IRWXU S_IRUSR S_IWUSR S_IXUSR
  S_IRWXG S_IRGRP S_IWGRP S_IXGRP
  S_IRWXO S_IROTH S_IWOTH S_IXOTH

  # Setuid/Setgid/Stickiness/SaveText.
  # Note that the exact meaning of these is system dependent.
  S_ISUID S_ISGID S_ISVTX S_ISTXT

  # File types.  Not necessarily all are available on your system.
  S_IFREG S_IFDIR S_IFLNK S_IFBLK S_IFCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT
);

my %mask;
foreach my $sym ($perldoc_f_stat =~ /\b(S_I\w+)\b/g) {
  my $val = eval { no strict 'refs'; &$sym() };
  if (defined $val) {
    $mask{$sym} = $val;
  }
  else {
    printf "%-10s - undefined\n", $sym;
  }
}

my @descending = sort { $mask{$b} <=> $mask{$a} } keys %mask;
printf "%-10s - %9o\n", $_, $mask{$_} for @descending;

在 Red Hat Enterprise Linux 和 System V 系列中的其他操作系统上，上述程序的输出将是

S_ISTXT - 未定义
S_IFWHT - 未定义
S_IFSOCK - 140000
S_IFLNK - 120000
S_IFREG - 100000
S_IFBLK - 60000
S_IFDIR - 40000
S_IFCHR - 20000
S_IFIFO - 10000
S_ISUID - 4000
S_ISGID - 2000
S_ISVTX - 1000
S_IRWXU - 700
S_IRUSR - 400
S_IWUSR - 200
S_IXUSR - 100
S_IRWXG - 70
S_IRGRP - 40
S_IWGRP - 20
S_IXGRP - 10
S_IRWXO - 7
S_IROTH - 4
S_IWOTH - 2
S_IXOTH - 1

有点玩弄

上面的数字是八进制（以 8 为底），所以任何给定的数字必须是 0-7 并且位值是 8 ⁿ，其中n是小数点左侧从零开始的位数。要查看它们如何映射到位，八进制具有每个数字对应于三个位的便利属性。四、二和 1 都是 2 的精确幂，因此在二进制中，它们分别是 100、10 和 1。二进制中的七（= 4 + 2 + 1）是 111，所以 70 ₈是 111000 ₂。后一个示例显示了来回转换是多么简单。

使用位字段，您并不关心该位置的位值究竟是什么，而是它是零还是非零，所以

if ($mode & $mask) {

$mode测试是否设置了对应的任何位$mask。举个简单的例子，给定 4 位整数 1011 和掩码 0100，它们的按位与为

  1011
& 0100
------
  0000

所以那个位置的位是明确的——而不是像 0010 或 1100 这样的掩码。

清除 1011 的最高位看起来像

    1011      1011
& ~(1000) = & 0111
            ------
              0011

回想一下，~在 Perl 中是按位补码。

为了完整起见，使用按位或设置一个位，如

$bits |= $mask;

八进制和文件权限

八进制数字直接映射到三位对于 Unix 权限来说很方便，因为它们以三个一组的形式出现。例如，产生上述输出的程序的权限是

-rwxr-xr-x 1 gbacon 用户 1096 Feb 24 20:34 modebits

即所有者可以读、写和执行；但其他人都可以阅读和执行。在八进制中，这是 755——一个紧凑的速记。根据上表，模式中的设置位为

S_IRUSR
S_IWUSR
S_IXUSR
S_IRGRP
S_IXGRP
S_IROTH
S_IXOTH

我们可以通过在上面的程序中添加几行来从您的问题中分解模式。

my $mode = 33188;
print "\nBits set in mode $mode:\n";
foreach my $sym (@descending) {
    if (($mode & $mask{$sym}) == $mask{$sym}) {
        print "  - $sym\n";
        $mode &= ~$mask{$sym};
    }
}

printf "extra bits: %o\n", $mode if $mode;

模式测试必须更加小心，因为某些掩码是多个位的简写。当一些位被设置但不是全部时，测试我们得到准确的掩码可以避免误报。

该循环还清除所有检测到的命中中的位，因此最后我们可以检查我们是否已经考虑了每个位。输出是

在模式 33188 中设置的位：
  - S_IFREG
  - S_IRUSR
  - S_IWUSR
  - S_IRGRP
  - S_IROTH

没有额外的警告，所以我们得到了一切。

那魔法07777

将 7777 ₈转换为二进制给出0b111_111_111_111. 回想一下，7 ₈是 111 ₂，四个 7 对应于 4×3 个。此掩码对于选择最后 12 个中的设置位很有用。回顾我们之前生成的位掩码

S_ISUID - 4000
S_ISGID - 2000
S_ISVTX - 1000
S_IRWXU - 700
S_IRWXG - 70
S_IRWXO - 7

我们看到最后 9 位是用户、组和其他的权限。前面的三位是 setuid、setgroupid 和有时称为粘滞位的东西。例如，sendmail我系统上的完整模式是-rwxr-sr-xor 34285 ₁₀。按位 AND 的结果是

  (dec)      (oct)                (bin)
  34285     102755     1000010111101101
&  4095 = &   7777 = &     111111111111
-------   --------   ------------------
   1517 =     2755 =        10111101101

被丢弃的模式中的高位是S_IFREG，表示它是一个常规文件。请注意，与以十进制或二进制表示的相同信息相比，以八进制表示的模式要清晰得多。

该stat文档提到了一个有用的功能。

……S_IF*功能是

S_IMODE($mode)
包含$mode权限位和 setuid/setgid/sticky 位的部分

在ext/Fcntl/Fcntl.xs中，我们在最后一行找到了它的实现和一个熟悉的常量。

void
S_IMODE(...)
    PREINIT:
        dXSTARG;
        SV *mode;
    PPCODE:
        if (items > 0)
            mode = ST(0);
        else {
            mode = &PL_sv_undef;
            EXTEND(SP, 1);
        }
        PUSHu(SvUV(mode) & 07777);

为了避免源代码中幻数的不良做法，请编写

my $permissions = S_IMODE $mode;

Fcntl 模块提供的usingS_IMODE和其他功能也隐藏了低级位旋转，并专注于程序想要的域级信息。文档继续

S_IFMT($mode)
包含文件类型的部分，可以使用（例如）或以下函数$mode进行位与运算S_IFREG

# The operators -f, -d, -l, -b, -c, -p, and -S.
S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode)
S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode)

# No direct -X operator counterpart, but for the first one
# the -g operator is often equivalent.  The ENFMT stands for
# record flocking enforcement, a platform-dependent feature.
S_ISENFMT($mode) S_ISWHT($mode)

使用这些常量和函数将通过更直接地表达您的意图使您的程序更清晰。

score 7 · Accepted Answer

perldoc -f stat对此进行了解释，我假设您在这里找到了这个示例：

Because the mode contains both the file type and its
permissions, you should mask off the file type portion and
(s)printf using a "%o" if you want to see the real permissions.

的输出printf "%04o", 420是0644文件的权限。420只是八进制数的十进制表示0644。

如果您尝试以二进制形式打印数字，则更容易看到：

perl -lwe 'printf "%016b\n", 33188'
1000000110100100
perl -lwe 'printf "%016b\n", 33188 & 07777'
0000000110100100

您会注意到，按位and删除上面数字中最左边的位，这可能代表文件类型，只留下文件权限。这个数字 07777 是二进制数：

perl -lwe 'printf "%016b\n", 07777'
0000111111111111

它在 bitwise 中充当“掩码” and。由于 1 & 1 = 1，且 0 & 1 = 0，这意味着任何与 07777 中的 1 不匹配的位都设置为 0。

linux - 从 stat 函数输出中理解和解码文件模式值

2 回答 2

模式位

有点玩弄

八进制和文件权限

那魔法07777

Related

Reference