1

我有一个文本文件，我有兴趣只拥有其中的一部分，所有内容都包含在 wordA 和 wordB 之间

可以使用 cmd 批处理文件吗？

4

3 回答 3

3

这是一种方法。假设 wordA 和 wordB 在同一行（两者都必须存在）。子例程 :FindString 删除不需要的前面文本，然后将“wordB”替换为我们不希望出现在文本中的字符，然后将其用作分隔符（在本例中为`）。必要时使用另一个字符。

@ECHO OFF
SET InFile=Test.txt

FOR /F "tokens=*" %%A IN ('FINDSTR "wordA" "%InFile%" ^| FINDSTR "wordB"') DO CALL :FindString "%%A"
pause
GOTO :eof

:FindString
SET String=%~1
SET String=%String:*wordA =%
SET String=%String: wordB=`%
FOR /F "tokens=1 delims=`" %%A IN ('ECHO.%String%') DO ECHO.%%A]
GOTO :eof
于 2013-02-24T03:44:33.807 回答
1

当“wordA”和“wordB”不在同一行时，这是一种方法。它将输出发送到 Output.txt。这将是输入文件中第一个“wordA”和第一个“wordB”之间的文本（区分大小写）。如果有多个（或不匹配的）wordA/B 集，您没有指定要做什么。

:RemoveWordB 将“wordB”替换为我们不希望出现在文本中的字符，然后将其用作分隔符（在本例中为`）。必要时使用另一个字符。

@ECHO OFF
SET InFile=Test.txt
SET OutFile=Output.txt
IF EXIST "%OutFile%" DEL "%OutFile%"
SET TempFile=Temp.txt
IF EXIST "%TempFile%" DEL "%TempFile%"

FOR /F "tokens=*" %%A IN ('FINDSTR /N "wordA" "%InFile%"') DO (
   CALL :RemovePrecedingWordA "%%A"
   FOR /F "tokens=1 delims=:" %%B IN ('ECHO.%%A') DO (
      MORE +%%B "%InFile%"> "%TempFile%"
      FINDSTR /V "wordB" "%TempFile%">> "%OutFile%"
      FOR /F "tokens=*" %%C IN ('FINDSTR "wordB" "%InFile%"') DO (
         CALL :RemoveWordB "%%C"
         IF EXIST "%TempFile%" DEL "%TempFile%"
         GOTO :eof
         )
      )
   )
GOTO :eof

:RemovePrecedingWordA
SET String=%~1
SET String=%String:*wordA =%
ECHO.%String%> "%OutFile%"
GOTO :eof

:RemoveWordB
REM Replace "wordB" with a character that we don't expect in text that we will then use as a delimiter (` in this case)
SET LastLine=%~1
SET LastLine=%LastLine:wordB=`%
FOR /F "tokens=1 delims=`" %%A IN ('ECHO.%LastLine%') DO ECHO.%%A>> "%OutFile%"
GOTO :eof
于 2013-02-24T15:19:07.353 回答
1

repl.bat这使用从 - http://www.dostips.com/forum/viewtopic.php?f=3&t=3855调用的帮助程序批处理文件

放在repl.bat与批处理文件相同的文件夹中。

@echo off
type infile |repl ".*wordA(.*)wordB.*" "$1" >outfile
于 2013-10-18T18:59:17.610 回答