1

我有一个关于 grep 的问题。我正在寻找多行文本中的特定模式。同一行通常有多个匹配项。我已经弄清楚如何提取我的模式，但是 grep 将每个匹配项放在一个新行上。有什么办法可以阻止 grep 这样做吗？理想情况下，我希望提取所有匹配项并保留原始文件的行结构。

这是一个例子：

一个输入行（其中有数千行）：

MUC3A|ENST00000414964[in] MUC3A|ENST00000422757[in] MUC3A|ENST00000319509[in] MUC3A|ENST00000483133[in] RP11-395B7.2.1|ENST00000420080[me] RP11-395B7.2.1|ENST00000438198[me] RP11-395B7.2.1|ENST00000434775[5g] MUC12|ENST00000536621[5g] MUC12|ENST00000379442[5g] MUC3A|ENST00000480291[5g]

我的 grep 命令：

grep -oe MUC12[\|A-Za-z0-9-]*\[[A-Za-z0-9]*\]

我当前的输出：

MUC12|ENST00000536621[5g]
MUC12|ENST00000379442[5g]

我的理想输出：

MUC12|ENST00000536621[5g] MUC12|ENST00000379442[5g]

有任何想法吗？我将非常感谢任何人可以提供的任何见解。

4

2 回答 2

1 
$ awk '{
   s=""
   for (i=1;i<=NF;i++) {
      if ($i ~ /MUC12[\|A-Za-z0-9-]*\[[A-Za-z0-9]*\]/) {
         printf "%s%s",s,$i
         s=" "
      }
   }
   print ""
}' file
MUC12|ENST00000536621[5g] MUC12|ENST00000379442[5g]

我会稍微更改您的 RE 以锚定表达式，使用字符类而不是显式范围以实现简洁和可移植性，并查找 1 个或多个字符 (+) 而不是允许零 (*)：

$ awk '{
   s=""
   for (i=1;i<=NF;i++) {
      if ($i ~ /^MUC12\|[[:alnum:]-]+\[[[:alnum:]]+\]$/) {
         printf "%s%s",s,$i
         s=" "
      }
   }
   print ""
}' file
MUC12|ENST00000536621[5g] MUC12|ENST00000379442[5g]

我也移动了“|” 在字符列表之外，因为它似乎不属于您发布的示例输入中的内容。

于 2013-02-21T13:07:11.673 回答
1

当您设置-o标志时，grep将在新行上分别打印每个匹配项，并且无法更改此行为。简单的解决方法是grep打印出每场比赛的行号，然后加入连续编号的行。您可以使用它awk来执行此操作。像这样运行：

< file grep -one "MUC12[\|A-Za-z0-9-]*\[[A-Za-z0-9]*\]" | awk -f script.awk

内容script.awk：

BEGIN {
    FS=":"
}

$1 == y {
    sub(/[^:]+:/,"")
    r = (r ? r OFS : "") $0
    next
}

x {
    print x, r
    r=""
}

{
    x=$0
    y=$1
    sub(/[^:]+:/,"",x)
}

END {
    print x, r
}

或者，这是单线：

< file grep -one "MUC12[\|A-Za-z0-9-]*\[[A-Za-z0-9]*\]" | awk -F ":" '$1 == y { sub(/[^:]+:/,""); r = (r ? r OFS : "") $0; next } x { print x, r; r="" } { x=$0; y=$1; sub(/[^:]+:/,"",x) } END { print x, r }'

这里介绍的方法可以应用于任何由grep. 与公认的答案不同，这种方法对于非空格分隔的正则表达式不会失败 - 这可能非常重要。

于 2013-02-21T15:55:02.513 回答