3

我有以下代码块，可以获取树下节点的名称，如下所示：

section/page/subPage

但我希望能够将其归结为以下内容（只是弥补）：

section[@id='someId']/page/subPage[@user='UserA']/@title

我从这些 StackOverflow 帖子之一中找到了以下代码：


<xsl:attribute name="path">
  <xsl:for-each select="ancestor-or-self::*">
    <xsl:if test="name() != 'root'">
      <xsl:value-of select="name()">
        <xsl:if test="not(position()=last())">
          <xsl:text>/</xsl:text>
        </xsl:if>
      </xsl:value-of>
    </xsl:if>
  </xsl:for-each>
</xsl:attribute>

这给了我一条直接的道路，但我想在它上面运行更多的逻辑来使它包含@id（或相关属性），也许还有一些我现在想不到的东西。

做这个的最好方式是什么？

我已经检查了 EXSLT 函数，这可能有效，但也许你们已经用更好的方法解决了这个问题。

有任何想法吗？

如果有帮助，我正在使用 ruby​​ 的 nokogiri 来解析 xml/xslt。

非常感谢，兰斯

4

2 回答 2

4

此解决方案可以满足您的要求：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="yes" />

  <xsl:template match="/">
    <root>
      <xsl:attribute name="path">
        <xsl:apply-templates select="(//@title)[1]" mode="make-path" />
      </xsl:attribute>
    </root>
  </xsl:template>

  <xsl:template match="*|@*" mode="make-path">
    <xsl:apply-templates select="parent::*" mode="make-path" />
    <xsl:text>/</xsl:text>
    <xsl:apply-templates select="." mode="make-name" />
    <xsl:choose>
      <xsl:when test="self::section">
        <xsl:apply-templates select="@id" mode="make-predicate" />
      </xsl:when>
      <xsl:when test="self::subPage">
        <xsl:apply-templates select="@user" mode="make-predicate" />
      </xsl:when>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="*|@*" mode="make-predicate">
    <xsl:text>[</xsl:text>
    <xsl:apply-templates select="." mode="make-name" />
    <xsl:text> = '</xsl:text>
    <xsl:value-of select="." />
    <xsl:text>']</xsl:text>
  </xsl:template>

  <xsl:template match="*" mode="make-name">
    <xsl:value-of select="name()" />
  </xsl:template>

  <xsl:template match="@*" mode="make-name">
    <xsl:text>@</xsl:text>
    <xsl:value-of select="name()" />
  </xsl:template>

</xsl:stylesheet>

当应用于

<section id="someId">
  <page>
    <subPage user="UserA" title="test" />
    <subPage user="UserB" title="blah" />
  </page>
  <page>
    <subPage user="UserC" title="fooh" />
  </page>
</section>

你得到：

<root path="/section[@id = 'someId']/page/subPage[@user = 'UserA']/@title" />

是可配置的<xsl:choose>点（添加任意数量<xsl:when>的 s）：

<!-- test for element name -->
<xsl:when test="self::section">
  <!-- make predicates out of selected attributes -->
  <xsl:apply-templates select="@id" mode="make-predicate" />
</xsl:when>

也可以：

<xsl:when test="self::section">
  <xsl:apply-templates select="@name|@category|subElement" mode="make-predicate" />
</xsl:when>

这将导致

<root path="/section[@name = 'someName'][@category = 'somecat'][subElement = 'xyz']/..." />

我看到的唯一问题是包含单引号的谓词值。他们会破坏 XPath。

于 2009-09-30T12:59:16.513 回答
1

对于每个祖先节点，您可以使用简单的 xsl:for-each 遍历所有属性

<xsl:for-each select="@*">

然后您可以使用这些属性来构建 XPath 字符串

<xsl:for-each select="ancestor-or-self::*">
   <xsl:if test="name() != 'root'">
      <xsl:value-of select="name()"/>
      <xsl:if test="@*">
         <xsl:text>[</xsl:text>
         <xsl:for-each select="@*">
            <xsl:text>@</xsl:text>
            <xsl:value-of select="name()"/>
            <xsl:text>='</xsl:text>
            <xsl:value-of select="."/>
            <xsl:text>'</xsl:text>
            <xsl:if test="not(position()=last())">
               <xsl:text> and </xsl:text>
            </xsl:if>
         </xsl:for-each>
         <xsl:text>]</xsl:text>
      </xsl:if>
      <xsl:if test="not(position()=last())">
         <xsl:text>/</xsl:text>
      </xsl:if>
   </xsl:if>
</xsl:for-each>
于 2009-09-30T12:46:30.567 回答