6

如何以编程方式检查文件夹的创建文件权限？修改文件权限？删除文件权限？
GetNamedSecurityInfo返回我可以写入C:\Program Files但 UAC 说Access Denied (5)
如何有效地确定访问权限？

我的代码：

function GetAccessRights(const FileName: String; ObjectType: SE_OBJECT_TYPE; 
  var Access: Cardinal): Cardinal;
var
  SecDesc: PSECURITY_DESCRIPTOR;
  pDacl: PACL;
  Trusteee: TRUSTEE_;
begin
  result := GetNamedSecurityInfo(PChar(FileName), ObjectType, 
    DACL_SECURITY_INFORMATION, nil, nil, @pDacl, nil, SecDesc);
  if ERROR_SUCCESS = result then
  begin
    // the pDacl may be NULL if the object has unrestricted access
    if pDacl <> nil then
    begin
      with Trusteee do
      begin
        pMultipleTrustee := nil;
        MultipleTrusteeOperation := NO_MULTIPLE_TRUSTEE;
        TrusteeForm := TRUSTEE_IS_NAME;
        TrusteeType := TRUSTEE_IS_UNKNOWN;
        ptstrName := 'CURRENT_USER';
      end;
      result := GetEffectiveRightsFromAcl(pDacl^, Trusteee, Access);
    end
    else
    begin
      Access := $FFFFFFFF;
      result := ERROR_SUCCESS;
    end;
    if SecDesc <> nil then
      LocalFree(Cardinal(SecDesc));
  end;
end;
4

1 回答 1

9

我一直在用NT Utilities这个。使用 Win2K/XP/Vista/7 对我来说效果很好

我的设置项目中的示例：

uses unitNTSecurity;

function CheckAccessToFile(DesiredAccess: DWORD; const FileOrDirName: string; ObjectName: string): Boolean;
var
  fo: TNTFileObject;
  acl: TAccessControlList;
  ace: TAccessControlElement;
  name: string;
  i: integer;
begin
  Result := False;
  if FileExists(FileOrDirName) or DirectoryExists(FileOrDirName) then
  begin
    fo := TNTFileObject.Create(FileOrDirName);
    acl := TAccessControlList.Create;
    try
      fo.GetDiscretionaryAccessList(acl);
      for i := 0 to acl.ElementCount - 1 do
      begin
        ace := acl.Element[i];
        name := ace.Name; // format is: BUILTIN\Users
        if (CompareText(ObjectName, name) = 0) and
          (ace.Type_ = aeAccessAllowed) and
          (DesiredAccess = ace.Mask) then
        begin
          Result := True;
          Break;
        end;
      end;
    finally
      fo.Free;
      acl.Free;
    end;
  end;
end;

检查modify权限：

Result := CheckAccessToFile($001301BF, 'C:\foo', 'BUILTIN\Users');

关于我的回答的注释：上面的代码回答了 OP 问题：

如何以编程方式检查修改权限

但是，如果您需要做的就是检查您的应用程序是否能够写入目录，我不会采用这种 ACL 解决方案，而是尝试向其中写入一个临时文件，这样我就可以100% 确定我可以写信给它。

我将此代码用作我需要授予modify某些目录权限的设置过程的一部分，因此此代码用于检查该目录是否还没有这些权限 - 这可能与您的情况截然不同。

关于这个问题有几个讨论：

所以你需要根据你的实际场景来选择你的解决方案。

于 2013-02-18T14:48:51.957 回答