2

我有一个 XML 文件，其中包含@url元素的属性<matimage>。目前@url属性中有一个特定的图像名称，比如triangle.png. 我想应用 XSLT 并修改此 URL，使其类似于assets/images/triangle.png.

我尝试了以下 XSLT：

<?xml version="1.0"?>
 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" />

  <!-- Copy everything -->
  <xsl:template match="*">
    <xsl:copy>
     <xsl:copy-of select="@*" />
     <xsl:apply-templates />
   </xsl:copy>
  </xsl:template>

 <xsl:template match="@type[parent::matimage]">
   <xsl:attribute name="uri">
     <xsl:value-of select="NEW_VALUE"/>
   </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

作为第一步，我尝试用新值替换旧值，但这似乎不起作用。请告诉我如何为@url属性的现有值添加或附加新值。

这是示例 XML：

   <material>
    <matimage url="triangle.png">
        Some text
    </matimage>
  </material>

期望的输出：

   <material>
    <matimage url="assets/images/triangle.png">
        Some text
    </matimage>
  </material>
4

1 回答 1

5

您想要实现的解决方案可能是：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <!-- Identity template : copy elements and attributes -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template> 

    <!-- Match all the attributes url within matimage elements -->
    <xsl:template match="matimage/@url">
        <xsl:attribute name="url">
            <!-- Use concat to prepend the value to the current value -->
            <xsl:value-of select="concat('assets/images/', .)" />
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>
于 2013-02-18T11:22:32.753 回答