1

我有 xml 结构，可以在其中加载程序的大部分数据。在这种情况下，我想实例化一个在 xml 中指定的类。我想我可以在 xml 中编写类的名称，然后实例化它并将参数传递给它。原来这并不容易！

我试过这样的代码：

            //special objects
        for each (o in xml.Objects[0].special) 
        { 
            p.x = o.@x;
            p.y = o.@y;
            s.x = o.@width;
            s.y = o.@height;
            trace(o.@classname);
            //var type:Class = o.@classname as Class;
            var type:Class = getDefinitionByName(String(o.@classname)) as Class;

            trace(type);
            objectArray.push(new type(p, s)); 
            trace("special");
        }

如您所见，我在 xml 文件的类名属性中有我的类的名称。我设法用 getDefinitionByName 获得了定义（至少下一个跟踪显示正确的类名）但是当我尝试实例化它并将它推入数组时，我得到一堆开始的错误

错误 #2136：SWF 文件 file:///Users/tuomas/Dropbox/Flash/ScorpionBox/bin-debug/ScorpionBox.swf 包含无效数据。

知道我应该怎么做吗？

4

1 回答 1

4

假设您的 XML 类型定义由 获得的限定名称组成getQualifiedClassName()，实例化类型并根据需要应用属性。

由 xml 定义的显示对象的示例实例化：

package
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class XmlParser extends Sprite
    {
        public var xml:XML = <objects>
                                <object type="flash.display::Sprite" x="0" y="0" width="100" height="100" />
                                <object type="flash.display::MovieClip" x="0" y="0" width="100" height="100" />
                             </objects>;

        public function XmlParser()
        {
            for each (var object:XML in xml.children())
            {
                var type:Class = getDefinitionByName(object.@type) as Class;
                var instance:DisplayObject = new type();
                instance.x = object.@x;
                instance.y = object.@y;
                instance.width = object.@width;
                instance.height = object.@height;

                addChild(instance);
            }
        }
    }
}

您还可以在序列化为 XML 时描述类型对象，然后通过迭代 XML 的属性将属性应用回对象实例，例如：

package
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class XmlParser extends Sprite
    {
        public var xml:XML = <objects>
                                <object type="flash.display::Sprite" x="0" y="0" width="100" height="100" />
                                <object type="flash.display::MovieClip" x="0" y="0" width="100" height="100" />
                             </objects>;

        public function XmlParser()
        {
            for each (var object:XML in xml.children())
            {
                var type:Class = getDefinitionByName(object.@type) as Class;
                var instance:DisplayObject = new type();
                addChild(instance);

                for each (var attribute:XML in object.@*)
                {
                    if(attribute.name() == "type") { continue; }

                    trace("setting: " + attribute.name() + " = " + attribute.toXMLString());
                    instance[attribute.name().toString()] = attribute.toXMLString();
                }
            }
        }
    }
}
于 2013-02-17T21:36:35.000 回答