1

我正在使用 FlashDevelop 在 Flex 中编写一个移动应用程序，并使用 Flash CS6 创建视觉资产。我在 Flash CS6 中创建了一个符号，并将其作为 AC3 导出到 SWC，然后将其导入到我的 FlashDevelop 项目中。然后我为它创建了一个类，如下所示：

package com 
{
import flash.display.Sprite;

  public class volmeter_class extends Sprite
  {
    private var design:volmeter;

    public function volmeter_class()
    {
        trace("I'm a MySymbol instance called", name);
        design = new volmeter();
        addChild(design);
    }     
  }  
}

我现在正在寻求在我的应用程序页面上显示我创建的符号。为此，我怀疑我应该以某种方式将它导入到我的 MXML 中，但我不知道该怎么做。有人可以给我一些关于如何开始这样做的提示吗？

4

1 回答 1

3

在 Flash Pro 中，确保为符号指定了 AS Linkage。

闪光符号

在项目的 ActionScript 构建路径中使用从 Flash Pro 发布的 SWC，可以通过 AS Linkage 实例化符号。或者，可以从 Flash Pro 的已发布 SWF 中嵌入符号。

纯 ActionScript 示例：

package
{
    import flash.display.Sprite;

    public class AppExample extends Sprite
    {
        public function AppExample()
        {
            var exampleSymbol:ExampleSymbol = new ExampleSymbol();
            addChild(exampleSymbol);
        }
    }
}

弹性 MXML 示例：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               creationComplete="creationCompleteHandler(event)">

    <fx:Script>
        <![CDATA[
            import mx.events.FlexEvent;

            protected function creationCompleteHandler(event:FlexEvent):void
            {
                var exampleSymbol:ExampleSymbol = new ExampleSymbol();
                symbol.addChild(exampleSymbol);
            }
        ]]>
    </fx:Script>

    <s:SpriteVisualElement id="symbol" />

</s:Application>

另一种方法是通过链接 Flash Pro 中的 SWF 来嵌入符号。

Flex MXML 嵌入示例：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark">

    <fx:Script>
        <![CDATA[
            [Embed('assets/library.swf', symbol = 'ExampleSymbol')]
            [Bindable]
            public static var ExampleSymbolClass:Class;
        ]]>
    </fx:Script>

    <s:Image source="{ExampleSymbolClass}" />

</s:Application>
于 2013-02-17T05:31:32.437 回答